Turismo

From eusterm

Nire proiektuaren abiapuntua UZEI Turismo hiztegia izango da. Hiztegiak 368 kontzeptu deskribatzen ditu. Hauexek dira hiztegian azaltzen diren datuak:

  • 368 kontzeptu
  • 394 euskarazko termino
  • 455 gaztelerazko termino
  • 475 ingelesezko termino
  • 473 frantsesezko termino
  • 144 euskarazko definizio
  • 0 gaztelerazko definizio
  • 0 ingelesezko definizio
  • 0 frantsesezko definizio

"Turismo" kontzeptu-eskema deskribatzen duen entitatea

Eskema honen kontzeptuak Q11918 entitateari lotuta daude.

Lanaren progresioa

Sarrera eta abiapuntua

Proiektu honen helburua turismoaren arloko terminologiaren azterketa eta definizioen osaketa da. Turismoa, sektore garrantzitsua izanik, hizkuntza eta kultura desberdinetan eragina du, eta horregatik, terminologia egokia eta osatua izatea funtsezkoa da. Proiektuaren hasieran, UZEI-ko hiztegi bat aurkitu nuen, turismoari buruzko terminoak biltzen zituena zenbait hizkuntzetan. Hiztegi honek euskaraz, gaztelaniaz, ingelesez eta frantzesez zenbait termino eskaintzen zituen. Hala ere, termino hauen definiziorik ez zegoen bertan.

Hain zuzen ere, azterketa egin ondoren, euskaraz 144 definizio zeudela ikusi nuen, ia 400 kontzeptu inguru daudenean. Hori dela eta, argi geratu zen definizioen osaketa lan handia eskatzen zuela. Gainera, beste hizkuntzetan, hala nola gaztelania, ingelesa eta frantsesa, definizioak falta ziren.

Lanaren helburuak eta pausuak

Nire lana, beraz, definizioen hutsuneak betetzean oinarrituko da. Terminologia aldetik, UZEI-ko hiztegia nahiko osatua dago, baina definizioak osatzeko beharra agerian geratu da. Horretarako, EUSTERM-etik definizioak zituen dokumentua OpenRefine aplikazioan sartu dut, eta bertan, Wikidata datu basearekin konparatuz joan naiz. Helburua izan da hizkuntza guztietan, ahal den neurrian, terminoaren eta Wikidataren arteko lotura bat aurkitzea.

Prozesu honetan, zenbait kasutan, terminoaren definizioa ez zen ulergarria edo egokia izan. Hori dela eta, azterketa sakonagoa egin behar izan nuen. Hala ere, kasu askotan, oraindik hutsuneak gelditzen ziren, eta horrek definizioen osaketa lanari jarraipena emateko beharra azpimarratzen du.

Oraingoan, Wikidata datu basearekin lortutako loturak egokiak diren hala ez aurkitzen naiz. Arazorik edo akatsak egonez, hauek aldatuz. Bestetik, terminoak zerrenda batean agertzen dira, eta ikusi dut kasuren batean bi ilaretan termino bera agertzen dela, bikoiztuta. Hauek ere aldatzen hari naiz, lanaren ulergarritasuna eta garbitasuna bermatzeko.

Nire beste lanetako bat, Wikidata datu baseko definizioak osatzea eta zuzentzea da. Izan ere, Wikidatan, kontzeptu baten eta honen definizioak agertzen dira zenbait hizkuntzetan. Hala nola, euskera, gaztelania, ingelesa eta frantzesa. Nire helburua, ahal den einean euskerazko eta beste hizkuntzetako definizioak osatzea da. Izan ere, ikusi dut, kasu askotan definizioak euskera ez ezik hizkuntza gehienetan aurkitzen ditugula. Beraz, euskarazkoak ere jartzea garrantzitsua iruditzen zait nire lanerako.

Honi gehituz, Eusterm eta Wikidata datu baseko lotura batzuk egokiak ez direla ikusi dudanez, 8 bat kontzeptutan hain zuzen, hauek zuzentzea izango da nire hurrengo zeregina. Hau da, lotura desegokiak ezabatuz. Honekin batera, kasu batzuetan, naiz eta terminoaren esanahia egokia izan, euskerazko kontzeptuaren izena ez zen egokia. Beraz, hau aldatu egin dut.

Horrela, Eusterm orrian Wikidatako loturarekin konparaketa egin dut. Honek zer esan nahi du? Ba bi baliabideetan definizioak egonez, bat bestea baino orokorragoa edo zehatzagoa dela zehaztu dut. Informazioa fusionatzeko orduan baliagarria baita hau egitea

Bestetik, Wikidata datu basean, normalean, editatzeko aukera librea dago. Definizioak eta kontzeptuan jarriz. Baina zenbait terminotan, konturatu naiz, orria "pribatua" agertzen dela. Beraz, zenbait kasutan, ezin izan dut editatu. Beraz, zeuden moduan gelditu behar izan dire orrialdeak. Honekin batera, definizioen formatoaren akatsak zuzentzerakoan, arazoak izan ditut. Izan ere, ezin nituen puntuak kendu, ezta hasierako letra larria erez. Beraz, ondoren eman beharreko pausua, Davidek egin dezake, automatikoki formatoa aldatuz.

Lanaren azken pausua, lortutako bi datu baseen informazioa, hau da, Eusterm eta Wikidatako informazioa, fusionatzea eta matzakatzea. Horrela, definizioetan agertutako hutsune asko betetzeko aukera izan dut. Hau nire helburua izanik. Horrela, lana osatuz eta jada zegoen informazioa hobetuz.

Wikidatara bidali beharrekoa

Bidali beharreko lana, hain zuzen ere, matxake horretan lortutako definizioak dira. Bai euskeraz, ingelesez, frantzesez eta gazteleraz. Hala ere, euskeraz zuzentudako kontzeptuak ere bidali beharra dira. Oso garrantzitsua baita euskerazko terminologia egokia izatea.



Datu-base galdeketak

Euskara-Gaztelera-Frantsesa-Ingelesa Hiztegia

Eskema honetako kontzeptuan hiztegi laueleduna ikusteko, erabili galdeketa hau. "uzeid" dutenak UZEI-ko "Turismo Hiztegia" lanetik datoz. 

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>

select ?concept ?uzeid
?euLabel (group_concat(distinct str(?euAltLabel);SEPARATOR="; ") as ?euAltLabels)  
?esLabel (group_concat(distinct str(?esAltLabel);SEPARATOR="; ") as ?esAltLabels)  
?enLabel (group_concat(distinct str(?enAltLabel);SEPARATOR="; ") as ?enAltLabels)  
?frLabel (group_concat(distinct str(?frAltLabel);SEPARATOR="; ") as ?frAltLabels)  
where {
  ?concept eusdp:P6 euswb:Q11918. 
  optional{?concept eusdp:P15 ?uzei_id. bind(xsd:integer(strafter(?uzei_id,"Turismo_")) as ?uzeid)}
  optional{?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu")}
  optional{?concept skos:altLabel ?euAltLabel. filter(lang(?euAltLabel)="eu")}
  optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
  optional{?concept skos:altLabel ?esAltLabel. filter(lang(?esAltLabel)="es")}
  optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
  optional{?concept skos:altLabel ?enAltLabel. filter(lang(?enAltLabel)="en")}
  optional{?concept rdfs:label ?frLabel. filter(lang(?frLabel)="fr")}
  optional{?concept skos:altLabel ?frAltLabel. filter(lang(?frAltLabel)="fr")}
  
 } group by ?concept ?uzeid ?euLabel ?euAltLabels ?esLabel ?esAltLabels ?enLabel ?enAltLabels ?frLabel ?frAltLabels
order by ?uzeid

Try it!

Hiztegitako definizioak

Eskema honetan agertzen diren definizioak ikusteko, erabili galdeketa hau. "uzeid" dutenak UZEI-ko "Turismo Hiztegia" lanetik datoz. 

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>

select ?concept ?uzeid
?euLabel ?euDescription
?esLabel ?esDescription
?enLabel ?enDescription 
?frLabel ?frDescription
where {
  ?concept eusdp:P6 euswb:Q11918. 
  optional{?concept eusdp:P15 ?uzei_id. bind(xsd:integer(strafter(?uzei_id,"Turismo_")) as ?uzeid)}
  optional{?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu")}
  optional{?concept schema:description ?euDescription. filter(lang(?euDescription)="eu")}
  optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
  optional{?concept schema:description ?esDescription. filter(lang(?esDescription)="es")}
  optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
  optional{?concept schema:description ?enDescription. filter(lang(?enDescription)="en")}
  optional{?concept rdfs:label ?frLabel. filter(lang(?frLabel)="fr")}
  optional{?concept schema:description ?frDescription. filter(lang(?frDescription)="fr")}
  
 } 
order by ?uzeid

Try it!

Wikidatarekin lotutako kontzeptuak

Erabili galdeketa hau ikusteko ea Wikidata loturak egokiak diren 

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>

select ?concept ?wikidata_item
?euLabel (group_concat(distinct str(?euAltLabel);SEPARATOR="; ") as ?euAltLabels)
?euDef
?esDef
?enDef
?wikidata_label ?wikidata_altLabels ?wikidata_def ?wikidata_enLabel ?wikidata_enDef ?wikidata_esLabel ?wikidata_esDef
where {
  ?concept eusdp:P6 euswb:Q11918.
  ?concept eusdp:P1 ?wd. bind (iri(concat(str(wd:),?wd)) as ?wikidata_item)
  optional{?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu")}
  optional{?concept skos:altLabel ?euAltLabel. filter(lang(?euAltLabel)="eu")}
  optional{?concept schema:description ?euDef. filter(lang(?euDef)="eu")}
  optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
  optional{?concept schema:description ?esDef. filter(lang(?esDef)="es")}
  optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
  optional{?concept schema:description ?enDef. filter(lang(?enDef)="en")}
  
  SERVICE <https://query.wikidata.org/sparql> { select ?wikidata_item ?wikidata_label (group_concat(distinct str(?wikidata_altLabel);SEPARATOR="; ") as ?wikidata_altLabels) ?wikidata_def ?wikidata_enLabel ?wikidata_enDef ?wikidata_esLabel ?wikidata_esDef
  WHERE { 
   ?wikidata_item rdfs:label ?wikidata_enLabel. filter(lang(?wikidata_enLabel)="en")
       optional {?wikidata_item rdfs:label ?wikidata_label. filter(lang(?wikidata_label)="eu")}
       optional {?wikidata_item schema:description ?wikidata_def. filter(lang(?wikidata_def)="eu")} 
       optional {?wikidata_item skos:altLabel ?wikidata_altLabel. filter(lang(?wikidata_altLabel)="eu")}
       optional{?wikidata_item schema:description ?wikidata_enDef. filter(lang(?wikidata_enDef)="es")}
       optional{?wikidata_item rdfs:label ?wikidata_esLabel. filter(lang(?wikidata_esLabel)="es")}
       optional{?wikidata_item schema:description ?wikidata_esDef. filter(lang(?wikidata_esDef)="es")}
                        } group by ?wikidata_item ?wikidata_label ?wikidata_altLabels ?wikidata_def ?wikidata_enLabel ?wikidata_enDef ?wikidata_esLabel ?wikidata_esDef
  }
  
 } group by ?concept ?wikidata_item ?euLabel ?euAltLabels ?euDef ?esLabel ?esAltLabels ?esDef ?enLabel ?enAltLabels ?enDef ?sareak ?wikidata_label ?wikidata_altLabels ?wikidata_def ?wikidata_enLabel ?wikidata_enDef ?wikidata_esLabel ?wikidata_esDef
order by lcase(?euLabel)

Try it!

Retrieved from "https://eusterm.wikibase.cloud/w/index.php?title=Turismo&oldid=50139"