Telefonia Hiztegia

Telefonia Hiztegia

• TBX Iturria: https://github.com/dlindem/wikibase/blob/main/eusterm/TBX/Telefonia%20Hiztegia_AD81.tbx
• PDF Iturria: https://www.euskadi.eus/contenidos/informacion/6503/es_2415/adjuntos/Hiztegiak/Telefonia_hiztegia.pdf
• Hiztegia deskribatzen duen Wikibase entitatea: Q10544

Telefonia hiztegia CC-BY lizentziapean argitaratua da TBX formatuan, 2019an (Eusko Jaurlaritzaren Argitalpen Zerbitzu Nagusiak 2017an argitaratu zuen PDFa, lizentzia librerik aipatu gabe). Lizentzia eta formatu horiek ahalbidetzen digute datu-multzo horrekin lan egitea, zenbait baldintzatan (ikus lizentzia).

Telefonia Hiztegiko sarrera guztiak

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>

select ?concept ?arloa
?euLabel ?euDescr (group_concat(distinct str(?euAltLabel);SEPARATOR="; ") as ?euAltLabels)  
?esLabel (group_concat(distinct str(?esAltLabel);SEPARATOR="; ") as ?esAltLabels)  
?enLabel (group_concat(distinct str(?enAltLabel);SEPARATOR="; ") as ?enAltLabels)  
?frLabel (group_concat(distinct str(?frAltLabel);SEPARATOR="; ") as ?frAltLabels)  
where {
  ?concept eusdp:P17 euswb:Q10544. # Telefonia hiztegia
  optional{?concept eusdp:P166 [rdfs:label ?arloa].}
  optional{?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu")}
  optional{?concept skos:altLabel ?euAltLabel. filter(lang(?euAltLabel)="eu")}
  optional{?concept schema:description ?euDescr. filter(lang(?euDescr)="eu")}
  optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
  optional{?concept skos:altLabel ?esAltLabel. filter(lang(?esAltLabel)="es")}
  optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
  optional{?concept skos:altLabel ?enAltLabel. filter(lang(?enAltLabel)="en")}
  optional{?concept rdfs:label ?frLabel. filter(lang(?frLabel)="fr")}
  optional{?concept skos:altLabel ?frAltLabel. filter(lang(?frAltLabel)="fr")}
  
 } group by ?concept ?arloa ?euLabel ?euDescr ?euAltLabels ?esLabel ?esAltLabels ?enLabel ?enAltLabels ?frLabel ?frAltLabels
order by ?arloa lcase(?euLabel)

Try it!

Wikidatarekin lerrotutako sarrerak

#title:Telefonia Hiztegiko kontzeptuak: Eustermen eta Wikidatan dituzten lexikalizazio hobetsiekin eta definizioekin
PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>

select ?eusterm_item ?UZEI_lex ?UZEI_def ?eusterm_label (group_concat(distinct str(?eusterm_altLabel);SEPARATOR="; ") as ?eusterm_altLabels) ?eusterm_def 
       ?wikidata_item ?wikidata_label ?wikidata_altLabels ?wikidata_endef ?wikidata_eudef ?wikipedia_en ?wikipedia_eu

where {
  ?eusterm_item eusdp:P17 euswb:Q10544; # Telefonia hiztegia;
           eusdp:P1 ?wd.
   bind (iri(concat(str(wd:),?wd)) as ?wikidata_item)
   optional {?eusterm_item eusdp:P8 ?UZEI_lex.}
   optional {?eusterm_item eusdp:P13 ?UZEI_def.}
  optional {?eusterm_item rdfs:label ?eusterm_label. filter(lang(?eusterm_label)="eu")}
  optional {?eusterm_item skos:altLabel ?eusterm_altLabel. filter(lang(?eusterm_altLabel)="eu")}
  optional {?eusterm_item schema:description ?eusterm_def. filter(lang(?eusterm_def)="eu")}
  
  SERVICE <https://query.wikidata.org/sparql> { select ?wd ?wikidata_item ?wikidata_label (group_concat(distinct str(?wikidata_altLabel);SEPARATOR="; ") as ?wikidata_altLabels) ?wikidata_endef ?wikidata_eudef ?wikipedia_en ?wikipedia_eu
  WHERE { 
   ?wikidata_item rdfs:label ?label. filter(lang(?label)="en")
       optional {?wikidata_item rdfs:label ?wikidata_label. filter(lang(?wikidata_label)="eu")}
       optional {?wikidata_item schema:description ?wikidata_eudef. filter(lang(?wikidata_eudef)="eu")} 
       optional {?wikidata_item schema:description ?wikidata_endef. filter(lang(?wikidata_endef)="en")}
       optional {?wikidata_item skos:altLabel ?wikidata_altLabel. filter(lang(?wikidata_altLabel)="eu")}
       optional {?wikipedia_en schema:about ?wikidata_item. filter(regex(str(?wikipedia_en), "en.wiki"))}
       optional {?wikipedia_eu schema:about ?wikidata_item. filter(regex(str(?wikipedia_eu), "en.wiki"))}
                        } group by ?wd ?wikidata_item ?wikidata_label ?wikidata_altLabels ?wikidata_endef ?wikidata_eudef ?wikipedia_en ?wikipedia_eu
  }
 } group by ?eusterm_item ?UZEI_lex ?UZEI_def ?eusterm_label ?eusterm_altLabels ?eusterm_def ?wikidata_item  ?wikidata_label ?wikidata_altLabels ?wikidata_endef ?wikidata_eudef ?wikipedia_en ?wikipedia_eu

Try it!