Saskibaloia

From eusterm

Nire proiektuaren abiapuntua UZEI Saskibaloia hiztegia izango da. Hiztegiak 366 kontzeptu deskribatzen ditu. Hauexek dira hiztegian azaltzen diren datuak:

  • 366 kontzeptu
  • 479 euskarazko termino
  • 459 gaztelerazko termino
  • 416 ingelesezko termino
  • 396 frantsesezko termino
  • 356 euskarazko definizio
  • 7 gaztelerazko definizio
  • 4 ingelesezko definizio
  • 4 frantsesezko definizio

"Saskibaloia" kontzeptu-eskema deskribatzen duen entitatea

Eskema honen kontzeptuak Q11440 entitateari lotuta daude.

Lanaren progresioa

Proiektuarekin hasi aurretik UZEI-ko Saskibaloia hiztegia aurkitu nuen kirolaren inguruko terminoak biltzen dituena. Hiztegiak euskeraz, gazteleraz, ingelesez eta frantsesez terminoak eskaintzen ditu, baina definizio aldetik nahiko pobrea da.

Lehenik, guztira zenbat kontzeptu dauden begiratu dut eta ondoren hizkuntza bakoitzean zenbat termino dauden. Terminoekin bukatutakoan, definizioetara joan naiz. Hizkuntza bakoitzean zenbat definizio dauden begiratu dut; gazteleraz, ingelesez eta frantsesez definizio gutxi daudela ikusi dezakegu. Euskeraz 356 definizio daude, nahiko aberatsa dela esan dezakegu kontutan harturik denetara 366 kontzeptu daudela. Definizioak begiratzeaz bukatutakoan, OpenRefine erabili dut Wikidata datu basearekin konparatzeko. Lau hizkuntzetan terminoaren eta Wikidataren arteko lotura egoki bat aurkitzea izan da nere helburua.

OpenRefine bidez “match” egiten definizio batzuk lotu ditut, baina oso gutxi iruditzen zaizkit dauden termino guztiak kontutan hartuz. Hasieran aplikazioarekin zenbait zailtasun izan nituen loturak egiten joateko, baina azkenean lotura batzuk egitea lortu nuen. Zenbait kasutan ez dut inolako loturarik lortu ez delako definizio hori edo desegokia delako. Loturak egiteaz bukatutakoan eta hutsune asko gelditu zaizkidala ikusi dudanean, definizioak osatzeko beharra ikusi dut.

Definizioak osatzen hasi aurretik, Q zenbaki guztiak izandakoan (guztira 72 izan dira), errepasatzen hasi naiz ea errenkada berean Q zenbaki berdinak zeuden. Kasu gutxi batzuetan errenkada berean zeuden Q zenbakiak desberdinak ziren (honek esan nahi du hizkuntza desberdinetan eginiko loturetako kontzeptuak eta beraz definizioak desberdinak direla) eta beraz zenbaki horietako bakoitzak ematen duen definizioa irakurri eta egokiena hautatu dut. Dena ondo zegoela ikusitakoan Q zenbakiak irakasleari bidali dizkiot eta Eusterm bidez beste galdeketa bat egin dut, ikusteko Eustermetik Wikidatara doazen loturak zuzenak ziren edo ez.

Galdeketa berri horretan aipatutako 72 definizioak zeuden. Galdetegiaren bitartez definizioak egoki dauden edo ez aztertu dut eta desegokiak ziren kasuetan, zuzendu egin ditut Q zenbaki egokiak bilatuz eta ordezkatuz. Zenbait kasutan Wikidatako Q zenbakia okerra izan da, baina ez dut zenbaki egokia topatu eta horregatik Wikidatako Q zenbakia ezabatu dut eta ez dut besterik jarri. Beste batzuetan aldiz, wikidatako definizioa egokia da baina oso orokorra; beraz Wikidatako Q zenbakiaren azpian bertako definizioa orokorragoa dela adierazi dut. Definizio guztiekin bukatutakoan, ziur egoteko, galdetegia berriz egin dut definizio guztiak errepasatuz. Zeregin honekin bukatutakoan ohartu naiz definizio askotan "Wikidatakoa orokorragoa" jarri behar izan dudala, kasu askotan definizioak ez dagokiola Saskibaloiaren arloari zehazki, baizik eta kirolaren arloari orokorrean.

Irakasleari zereginarekin bukatu dudala jakinarazi diot eta beste galdetegi bat egin dit. Oraingo galdetegi honetan adierazitako erlazio zehatzak (wikidatakoa orokorragoa) zein diren ere azaltzen dira. Galdetegi honen bidez berriro ere erlazio horiek errepasatu ditut eta oker daudenak, ezabatu edo zuzendu. Honekin bukatutakoan definizioetan zentratu naiz; hau da, lehenengo letra minuskulan jarri dut eta bukaerako puntua kendu. Honako hau definizio guztietan egin dut, baina zenbait definizio oso luzeak ziren eta beraz laburtu egin ditut soilik informazio garrantzitsuena utziz bertan.

Aurretik aipatu bezala, nire helburua definizioak osatzea izan da. Beraz, aurreko guztiarekin amaitutakoan, berriro ere "Hiztegietako Definizioak" izeneko galdetegira joan naiz eta bertako definizioak osatzen hasi naiz. Galdetegian denetara 366 definizio agertzen dira, horietako gehienek dute euskarazko definizioa, baina gazteleraz, ingelesez eta frantsesez falta dira eta horiek osatzea izan da nire helburua. Definizio guztiak osatzeaz bukatutakoan, ondorengoak izan dira geratu diren emaitzak: - 356 Euskarazko definizio. - 356 Gaztelerazko definizio. - 306 Ingelesezko definizio. - 305 Frantsesezko definizio.

Definizio hauek osatzerako orduan formatua kontutan hartu dut; hau da, lehenengo letra txikiz idatzi eta esaldiaren bukaeran punturik ez jarri. Aurretik aipatu bezala eta egin dudan bezala, definizioak osatu bitartean euskarazko definizio asko errepasatu gabe nituen. Beraz, definizio horiek errepasatzen joan naiz formatua egoki jarriz eta oso luzeak ziren definizioak laburbildu ditut soilik garrantzitsuena utziz. Hori egin ondoren, gainontzeko hizkuntzetako definizioak banan-banan osatu ditut. Zenbait kasutan, aldiz, hizkuntza batzuetan ez zegoen terminorik eta beraz terminorik ez zegoenetan ez dut definiziorik jarri.

Orain, nire projektuarekin bukatutakoan, orrialde honetan egindako eta azaldutakko guztia wikidatara bidaltzea izango da nire amaierako helburua. Hau egindakoan nire projektua guztiz bukatutzat emango dut.

Datu-base galdeketak

Euskara-Gaztelera-Frantsesa-Ingelesa Hiztegia

Eskema honetako kontzeptuan hiztegi laueleduna ikusteko, erabili galdeketa hau. "uzeid" dutenak UZEI-ko "Saskibaloia Hiztegia" lanetik datoz. 

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>

select ?concept ?uzeid ?wikidata
?euLabel ?euDescription
?esLabel ?esDescription
?enLabel ?enDescription 
?frLabel ?frDescription
where {
  ?concept eusdp:P6 euswb:Q11440. 
  optional{?concept eusdp:P15 ?uzei_id. bind(xsd:integer(strafter(?uzei_id,"Saskibaloia_")) as ?uzeid)}
  optional{?concept eusdp:P1 ?wikidata.}
  optional{?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu")}
  optional{?concept schema:description ?euDescription. filter(lang(?euDescription)="eu")}
  optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
  optional{?concept schema:description ?esDescription. filter(lang(?esDescription)="es")}
  optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
  optional{?concept schema:description ?enDescription. filter(lang(?enDescription)="en")}
  optional{?concept rdfs:label ?frLabel. filter(lang(?frLabel)="fr")}
  optional{?concept schema:description ?frDescription. filter(lang(?frDescription)="fr")}
  
 } 
order by ?uzeid

Try it!


Hiztegitako definizioak

Eskema honetan agertzen diren definizioak ikusteko, erabili galdeketa hau. "uzeid" dutenak UZEI-ko "Saskibaloia Hiztegia" lanetik datoz. 

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>

select ?concept ?uzeid
?euLabel ?euDescription
?esLabel ?esDescription
?enLabel ?enDescription 
?frLabel ?frDescription
where {
  ?concept eusdp:P6 euswb:Q11440. 
  optional{?concept eusdp:P15 ?uzei_id. bind(xsd:integer(strafter(?uzei_id,"Saskibaloia_")) as ?uzeid)}
  optional{?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu")}
  optional{?concept schema:description ?euDescription. filter(lang(?euDescription)="eu")}
  optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
  optional{?concept schema:description ?esDescription. filter(lang(?esDescription)="es")}
  optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
  optional{?concept schema:description ?enDescription. filter(lang(?enDescription)="en")}
  optional{?concept rdfs:label ?frLabel. filter(lang(?frLabel)="fr")}
  optional{?concept schema:description ?frDescription. filter(lang(?frDescription)="fr")}
  
 } 
order by ?uzeid

Try it!

Hiztegiko kontzeptuak, arloka antolatuta

Galdeketa honek grafo itxurako bisualizazio batera darama. 

#defaultView:Graph
PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>

select * where {

  ?concept eusdp:P6 euswb:Q11440. 
  ?concept rdfs:label ?conceptLabel. filter(lang(?conceptLabel)="eu")
  ?concept eusdp:P166 ?arlo.
  ?arlo rdfs:label ?arloLabel. filter(lang(?arloLabel)="eu")
  
 } order by ?arlo

Try it!

Wikidatarekin lotutako hiztegi honetako kontzeptuak

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>

select ?concept ?wikidata_item ?erlazioa
?euLabel (group_concat(distinct str(?euAltLabel);SEPARATOR="; ") as ?euAltLabels)
?euDef
?esDef
?enDef
?wikidata_label ?wikidata_altLabels ?wikidata_def ?wikidata_enLabel ?wikidata_enDef ?wikidata_esLabel ?wikidata_esDef
where {
  ?concept eusdp:P6 euswb:Q11440.
  ?concept eusp:P1 ?wd_st. ?wd_st eusps:P1 ?wd. bind (iri(concat(str(wd:),?wd)) as ?wikidata_item)
  optional{?wd_st euspq:P170 [rdfs:label ?erlazioa].}
  optional{?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu")}
  optional{?concept skos:altLabel ?euAltLabel. filter(lang(?euAltLabel)="eu")}
  optional{?concept schema:description ?euDef. filter(lang(?euDef)="eu")}
  optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
  optional{?concept schema:description ?esDef. filter(lang(?esDef)="es")}
  optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
  optional{?concept schema:description ?enDef. filter(lang(?enDef)="en")}
  
  SERVICE <https://query.wikidata.org/sparql> { select ?wikidata_item ?wikidata_label (group_concat(distinct str(?wikidata_altLabel);SEPARATOR="; ") as ?wikidata_altLabels) ?wikidata_def ?wikidata_enLabel ?wikidata_enDef ?wikidata_esLabel ?wikidata_esDef
  WHERE { 
   ?wikidata_item rdfs:label ?wikidata_enLabel. filter(lang(?wikidata_enLabel)="en")
       optional {?wikidata_item rdfs:label ?wikidata_label. filter(lang(?wikidata_label)="eu")}
       optional {?wikidata_item schema:description ?wikidata_def. filter(lang(?wikidata_def)="eu")} 
       optional {?wikidata_item skos:altLabel ?wikidata_altLabel. filter(lang(?wikidata_altLabel)="eu")}
       optional{?wikidata_item schema:description ?wikidata_enDef. filter(lang(?wikidata_enDef)="en")}
       optional{?wikidata_item rdfs:label ?wikidata_esLabel. filter(lang(?wikidata_esLabel)="es")}
       optional{?wikidata_item schema:description ?wikidata_esDef. filter(lang(?wikidata_esDef)="es")}
                        } group by ?wikidata_item ?wikidata_label ?wikidata_altLabels ?wikidata_def ?wikidata_enLabel ?wikidata_enDef ?wikidata_esLabel ?wikidata_esDef
  }
  
 } group by ?concept ?wikidata_item ?erlazioa ?euLabel ?euAltLabels ?euDef ?esLabel ?esAltLabels ?esDef ?enLabel ?enAltLabels ?enDef ?sareak ?wikidata_label ?wikidata_altLabels ?wikidata_def ?wikidata_enLabel ?wikidata_enDef ?wikidata_esLabel ?wikidata_esDef
order by lcase(?euLabel)

Try it!

Eusterm eta Wikidatako definizioak konparatzeko

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>

select ?concept ?wikidata_item ?erlazioa
?euLabel (group_concat(distinct str(?euAltLabel);SEPARATOR="; ") as ?euAltLabels)
?euDef
?wikidata_label ?wikidata_def ?wikidata_enDef ?wikidata_esDef
where {
  ?concept eusdp:P6 euswb:Q11440.
  ?concept eusp:P1 ?wd_st. ?wd_st eusps:P1 ?wd. bind (iri(concat(str(wd:),?wd)) as ?wikidata_item)
  optional{?wd_st euspq:P170 [rdfs:label ?erlazioa].}
  optional{?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu")}
  optional{?concept skos:altLabel ?euAltLabel. filter(lang(?euAltLabel)="eu")}
  optional{?concept schema:description ?euDef. filter(lang(?euDef)="eu")}
  optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
  optional{?concept schema:description ?esDef. filter(lang(?esDef)="es")}
  optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
  optional{?concept schema:description ?enDef. filter(lang(?enDef)="en")}
  
  SERVICE <https://query.wikidata.org/sparql> { select ?wikidata_item ?wikidata_label ?wikidata_def ?wikidata_enDef ?wikidata_esDef
  WHERE { 
   ?wikidata_item rdfs:label ?wikidata_enLabel. filter(lang(?wikidata_enLabel)="en")
       optional {?wikidata_item rdfs:label ?wikidata_label. filter(lang(?wikidata_label)="eu")}
       optional {?wikidata_item schema:description ?wikidata_def. filter(lang(?wikidata_def)="eu")} 
      
       optional{?wikidata_item schema:description ?wikidata_enDef. filter(lang(?wikidata_enDef)="es")}

       optional{?wikidata_item schema:description ?wikidata_esDef. filter(lang(?wikidata_esDef)="es")}
                        } 
  }
  
 } group by ?concept ?wikidata_item ?erlazioa ?euLabel ?euAltLabels ?euDef  ?wikidata_label ?wikidata_def ?wikidata_enDef  ?wikidata_esDef
order by lcase(?euLabel)

Try it!

Wikidatara bidalitako datuak

Eusterm eta Wikidata artean erabateko "match" egin duten kontzeptuen kasuetan, terminoak eta definizioak bidali egin ditugu: 

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>

select ?concept ?uzeid ?wikidata_item
?euLabel ?euDescription
?esLabel ?esDescription
?enLabel ?enDescription 
?frLabel ?frDescription
where {
  ?concept eusdp:P6 euswb:Q11440. 
  optional{?concept eusdp:P15 ?uzei_id. bind(xsd:integer(strafter(?uzei_id,"Saskibaloia_")) as ?uzeid)}
  ?concept eusp:P1 ?wd_st. ?wd_st eusps:P1 ?wd. bind (iri(concat(str(wd:),?wd)) as ?wikidata_item)
  filter not exists{?wd_st euspq:P170 [rdfs:label ?erlazioa].}
  optional{?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu")}
  optional{?concept schema:description ?euDescription. filter(lang(?euDescription)="eu")}
  optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
  optional{?concept schema:description ?esDescription. filter(lang(?esDescription)="es")}
  optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
  optional{?concept schema:description ?enDescription. filter(lang(?enDescription)="en")}
  optional{?concept rdfs:label ?frLabel. filter(lang(?frLabel)="fr")}
  optional{?concept schema:description ?frDescription. filter(lang(?frDescription)="fr")}
  
 } 
order by ?uzeid

Try it!

Retrieved from "https://eusterm.wikibase.cloud/w/index.php?title=Saskibaloia&oldid=50349"