Sare Sozialak

From eusterm

Sare Sozialak, kontzeptu-eskema bat

Kontzeptu-eskema hau errepresentatzen duen entitatea: Q5964

Proiektuaren deskribapena

Wikidatako galdeketa batetik abiatu naiz, sare sozial ezberdinen erabilitako "software features" direnak zerrendatzen dituena: https://w.wiki/7yms


Egilea

Ainhoa Rezola


Sarrera

Hemen jarraian ikusiko duzuena A hizkuntzaren terminologiako ikasgaierako sortu dudan proiektua da. Zehazki, sare sozialen inguruko teminologia arakatu dut, eta aurkitu dudan dokumentazio hori euskarara itzultzen aritu naiz.

Helburua

Nik sare sozialen inguruan dagoen dokumentazioa, eta termino guzti horien artetik euskarara itzulitakoa aztertu nuen. Informazio gehiena ingelesez dagoela jakin nuen, eta baita euskarara itzulitako terminoak nahiko gutxi direla ere, horregatik, esparru horretako hainbat terminoren euskarazko baliokidetasuna bilatu nahi izan dut. Horrela, gaur egun hainbesteko garrantzia duen esparru berri horretan euskarak indarra lortu dezan, eta ez dadin atzeratuta geratu.

Metodologia

Lehenik eta behin, Wikipediatik ingelesezko terminoak hartzea pentsatu nuen, baina bertan termino ugari zeuden eta batzuk ez zeuden hain modu zuzenean lotuta sare sozialen esparruarekin. Horregatik, Wikdiatan galdera bat egitea erabaki nuen eta galdera horretatik lortutako terminoak hartzea erabaki nuen. Bertan, oso gutxi ziren euskarazko lexikalizazioa zuten terminoak, eta beraz, UZEI hiztegitik ere hartu nituen terminoak. UZEIko terminoek Q zenbakirik ez zutenez, Openrefine bidez, termino ia guztiei Q zenbaki bat lotzea lortu nuen. Behin denek Q zenbakia izatea lortuta, hurrengo pausoa euskarazko lexikalizaziorik gabe geratutako terminoak nik eskuz bilatzea izan zen. Horrela, beste hainbat terminoren euskarazko lexikalizazioa aurkitzea lortu dut, baina agian ez hain orri fidagarrietan. Lexikalizazio berri horiek, Eusterm-en idatzi egin ditut. Eta dagoeneko, lehen baino askoz termino gehiago daude prest Wikidatara bidaltzeko, eta gainera, euskarazko lexikalizazioa edukita.

Iturriak

Aurretik aipatu dudan bezala, erabilitako iturri nagusiak Wikidata, UZEI hiztegia eta Openrefine izan dira. Nik gero eskuz bilatutako iturriak ere ugari izan dira; hala nola, Argia eta Berria aldizkariak...

Emaitzak

Proiektu honen bitartez, sare sozialen esparruko 221 termino ezberdin batu ditut eta Wikidatara bidali ditut beraien euskarazko lexikalizazioarekin batera. Euskarak gai horretan zuen presentzia murritza dela eta, nahiko ekarpen onuradun gisa ikusten dut nik proiektu honetan egindakoa. Proiektu honen jarraipen gisa, 221 termino hauen euskarazko definizioa idaztea irudikatzen dut, etorkizun batean.

SPARQL

Euskara-Gazteleraz-Ingelesezko hiztegia, definizioduna

Eskema honetako kontzeptuan hiztegi hirueleduna ikusteko, erabili galdeketa hau. 

#title:"Sare Sozialak" eskemako kontzeptuak hiru hizkuntzetan

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>

select ?concept (iri(concat("http://www.wikidata.org/wiki/",?wd)) as ?wikidata)
?euLabel (group_concat(distinct str(?euAltLabel);SEPARATOR="; ") as ?euAltLabels)
?euDef
?esLabel (group_concat(distinct str(?esAltLabel);SEPARATOR="; ") as ?esAltLabels)  
?esDef
?enLabel (group_concat(distinct str(?enAltLabel);SEPARATOR="; ") as ?enAltLabels)  
?enDef
(group_concat(distinct ?sareLabel;SEPARATOR=", ") as ?sareak)
where {
  ?concept eusdp:P6 euswb:Q5964.
  optional{?concept eusdp:P1 ?wd.}
  optional{?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu")}
  optional{?concept skos:altLabel ?euAltLabel. filter(lang(?euAltLabel)="eu")}
  optional{?concept schema:description ?euDef. filter(lang(?euDef)="eu")}
  optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
  optional{?concept skos:altLabel ?esAltLabel. filter(lang(?esAltLabel)="es")}
  optional{?concept schema:description ?esDef. filter(lang(?esDef)="es")}
  optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
  optional{?concept skos:altLabel ?enAltLabel. filter(lang(?enAltLabel)="en")}
  optional{?concept schema:description ?enDef. filter(lang(?enDef)="en")}
  optional{?concept eusdp:P50 ?sarea. ?sarea rdfs:label ?sareLabel. filter(lang(?sareLabel)="eu")}
  
 } group by ?concept ?wd ?euLabel ?euAltLabels ?euDef ?esLabel ?esAltLabels ?esDef ?enLabel ?enAltLabels ?enDef ?sareak
order by ?euLabel

Try it!


UZEI-ko eta Wikidata-ko kontzeptuak

Hemen, Sare Sozialak UZEI hiztegitik datozenak nahiz Wikidatarekin lerrokatutakoak agertzen dira: 

#title:"Sare Sozialak" eskemako kontzeptu guztiak
PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>

select ?concept ?uzeid (iri(concat("http://www.wikidata.org/entity/",?wd)) as ?wikidata)
?euLabel (group_concat(distinct str(?euAltLabel);SEPARATOR="; ") as ?euAltLabels)  
?esLabel (group_concat(distinct str(?esAltLabel);SEPARATOR="; ") as ?esAltLabels)  
?enLabel (group_concat(distinct str(?enAltLabel);SEPARATOR="; ") as ?enAltLabels)  
?frLabel (group_concat(distinct str(?frAltLabel);SEPARATOR="; ") as ?frAltLabels)  
where {
  ?concept eusdp:P6 euswb:Q5964. 
  optional{?concept eusdp:P15 ?uzei_id. bind(xsd:integer(strafter(?uzei_id,"sare_sozialak_")) as ?uzeid)}
  optional{?concept eusdp:P1 ?wd.}
  optional{?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu")}
  optional{?concept skos:altLabel ?euAltLabel. filter(lang(?euAltLabel)="eu")}
  optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
  optional{?concept skos:altLabel ?esAltLabel. filter(lang(?esAltLabel)="es")}
  optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
  optional{?concept skos:altLabel ?enAltLabel. filter(lang(?enAltLabel)="en")}
  optional{?concept rdfs:label ?frLabel. filter(lang(?frLabel)="fr")}
  optional{?concept skos:altLabel ?frAltLabel. filter(lang(?frAltLabel)="fr")}
  
 } group by ?concept ?uzeid ?wd ?euLabel ?euAltLabels ?esLabel ?esAltLabels ?enLabel ?enAltLabels ?frLabel ?frAltLabels
order by lcase(?enLabel)

Try it!

Euskarazko lexikalizazio eta definizioak

Hemen, Wikidatarekin lerrokatutakoak agertzen dira, eustermen eta wikidatan dituzten lexikalizazio eta definizioekin 

#title:"Sare Sozialak" eskemako kontzeptuak hiru hizkuntzetan, Eustermen eta Wikidatan

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>

select ?concept ?wikidata_item
?euLabel (group_concat(distinct str(?euAltLabel);SEPARATOR="; ") as ?euAltLabels)
?euDef
?esLabel (group_concat(distinct str(?esAltLabel);SEPARATOR="; ") as ?esAltLabels)  
?esDef
?enLabel (group_concat(distinct str(?enAltLabel);SEPARATOR="; ") as ?enAltLabels)  
?enDef
(group_concat(distinct ?sareLabel;SEPARATOR=", ") as ?sareak) ?wikidata_label ?wikidata_altLabels ?wikidata_def ?wikidata_enlabel 
where {
  ?concept eusdp:P6 euswb:Q5964.
  ?concept eusdp:P1 ?wd. bind (iri(concat(str(wd:),?wd)) as ?wikidata_item)
  optional{?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu")}
  optional{?concept skos:altLabel ?euAltLabel. filter(lang(?euAltLabel)="eu")}
  optional{?concept schema:description ?euDef. filter(lang(?euDef)="eu")}
  optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
  optional{?concept skos:altLabel ?esAltLabel. filter(lang(?esAltLabel)="es")}
  optional{?concept schema:description ?esDef. filter(lang(?esDef)="es")}
  optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
  optional{?concept skos:altLabel ?enAltLabel. filter(lang(?enAltLabel)="en")}
  optional{?concept schema:description ?enDef. filter(lang(?enDef)="en")}
  optional{?concept eusdp:P50 ?sarea. ?sarea rdfs:label ?sareLabel. filter(lang(?sareLabel)="eu")}
  
  SERVICE <https://query.wikidata.org/sparql> { select ?wikidata_item ?wikidata_label (group_concat(distinct str(?wikidata_altLabel);SEPARATOR="; ") as ?wikidata_altLabels) ?wikidata_def ?wikidata_enlabel
  WHERE { 
   ?wikidata_item rdfs:label ?wikidata_enlabel. filter(lang(?wikidata_enlabel)="en")
       optional {?wikidata_item rdfs:label ?wikidata_label. filter(lang(?wikidata_label)="eu")}
       optional {?wikidata_item schema:description ?wikidata_def. filter(lang(?wikidata_def)="eu")} 
       optional {?wikidata_item skos:altLabel ?wikidata_altLabel. filter(lang(?wikidata_altLabel)="eu")}
                        } group by ?wikidata_item ?wikidata_label ?wikidata_altLabels ?wikidata_def ?wikidata_enlabel
  }
  
 } group by ?concept ?wikidata_item ?euLabel ?euAltLabels ?euDef ?esLabel ?esAltLabels ?esDef ?enLabel ?enAltLabels ?enDef ?sareak ?wikidata_label ?wikidata_altLabels ?wikidata_def ?wikidata_enlabel 
order by lcase(?euLabel)

Try it!

Retrieved from "https://eusterm.wikibase.cloud/w/index.php?title=Sare_Sozialak&oldid=29578"