Kolore Izenak

From eusterm

Kolore Izenak, kontzeptu eskema bat

Kontzeptu-eskema errepresentatzen duen entitatea: Q3766

Egilea: Lorena Perez

Euskarazko kolore izenak bilatzen aritu naiz, excel bat osatuz. Bertan, eustermen euskaraz lexikalizaziorik agertzen ez zenean, baliokidea euskaraz bilatu eta taulan txertatu dut, adibide batekin eta hori aurkitu dudan linkarekin.

Abiapuntua

Wikidatatik atera ditugu "instance of color" guztiak: https://w.wiki/7pxH

Helburua eta Metodologia

A priori, koloreen gaia oso sinplea dirudi, baina, errealitatea guztiz kontrakoa da. Denok dakigu nola esaten den, edozein hizkuntzetan, gorria, morea edo are zuria. Beste modu batean erranda, kolore sinpleenen itzulpena egitea erraza da. Hala ere, gaia apur bat sakonduz gero, azkar konturatzen gara euskarazko koloreen arloan hutsune erraldoi bat dagoela. Hutsune hau txikiagoa bihurtzeko motibazio eta helburuarekin, nire proiektuari hasiera eman nion.

Sarean bilaketak egiten denbora dezente eman dut euskarazko lexikalizazioak bilatzeko. Hau erranda, horiek aurkitzeko prozesua hurrengoa izan da:

1. https://www.wikidata.org/wiki/Q3776737 wikidatako linka irekitzen nuen lexikalizazioa ze hizkuntzetan eskuragarri zegoen ikusteko.

2. Orokorrean, ingelesez lexikalizazioa beti zegoen eta kasu askotan, gaztelerazko bertsioa agertzen zen ere.

3. Beraz, hurrengo urratsa hiztegiak erabiliz ea euskarazko itzulpenik dagoen ikustea da. Horretarako, WordReference eta Elhuyar hiztegiak erabili ditut batez ere. 

     * Kasu honetan adibidez, hiztegiak erabiliz "Ash" gazteleraz "Ceniza" dela jakin dut eta euskaraz berriz, "Errauts".

4. Behin euskarazko bertsio posible bat dugunean, sarean murgiltzeko unea da. Atal honetan, kontu handiz ibili behar gara... 

     * Kontuz! webgune askok itzulpen automatikoak erabiltzen dituztelako euskarazko bertsioa eskaintzeko.

Hasieran kolore askoren itzulpenak aurkitu nituen baina gero, denborarekin, itzulpen automatikoak zirela konturatu nintzen. Hori dela eta, soilik bi webgune mota fidagarriak zirela jakin nuen:

- Alde batetik, .eus zeukaten webguneak.

- Eta bestetik, Egungo Testuen Corpusa webgunea.

5. Pauso guzti hauek egin eta gero, kolorearen itzulpena aurkitzerakoan, egindako excelean web orriaren linka eta itzulpena aurkitutako esaldia apuntatzen nituen.

6. Hala ere, itzulpen egokirik ez banuen aurkitzen, wikidatako hurrengo linka irekitzen nuen, lehendabiziko pausora itzuliz. 

     * Horrela behin eta berriro.

Ondorioak

Behin bilaketa hau eginda, ondorio gisa euskarazko koloreen itzulpenak hiru multzotan sailkatzen ahal direla aipa dezakegu:

1. Maileguak:

Euskarazko kolore asko, beste hizkuntzetako (frantsesa, ingelesa, gaztelera...) maileguak dira.

Hona hemen adibide batzuk

Beige --> Beix

Verde --> Berde

Morado --> More

2. "Gauzen" itzulpenak:

Euskarazko koloreen beste zati handi bat "gauzen" itzulpenak direla aipa genezake. Hauek lau azpi talde ezberdinetan kokatuko lirateke:

- Harrietatik datozen koloreak: errubi kolore, antrazita kolore,...

- Animalien izenetatik datozen koloreak: sagu kolore, sator kolore,...

- Landaretatik datozen koloreak: azafrai-kolore,...

- Janari ezberdinetatik datozen koloreak: ezti kolore, limoi kolore, marrubi kolore,...

Eta azkenik,

3. Termino propioak:

Ehuneko txiki batean gertatzen da euskarak kolore bat izendatzeko termino propioa daukala,adibide gisa arre terminoa aipa genezake. Hala ere, hau oso gutxitan ikus daiteke, jada aipatu bezala, askotan koloreak beste hizkuntzetako maileguak direlako. 

  * Askotan, itzulpena egiteko izen bateri "kolore" hitza gehitzearkin nahikoa badirudi, ez da beti horrela gertatzen. Adibideak hurrengoak izango lirateke: Frantzia urdin, berde-horixka, itsas urdin, eta abar luze bat.

Bukatzeko

Euskarari arlo honetan ekarpen handia egin dudala uste dut, izan ere, 167 terminoko hutsunea bete dugu WikiData eta Eusterm-en. Hau erranda, oso gustora aritu naiz lan hau egiten.

Etorkizunari begira hala ere, oraindik lan asko egiteko dago: 600 terminoei itzulpena aurkitzea, subclass of atala sakontzea...

SPARQL

Euskara-Gazteleraz-Ingelesezko hiztegia, definizioduna

Eskema honetako kontzeptuan hiztegi hirueleduna ikusteko, erabili galdeketa hau. 

#title:"Koloreak" eskemako kontzeptuak hiru hizkuntzetan

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>
PREFIX eusno: <https://eusterm.wikibase.cloud/prop/novalue/>

select ?concept (iri(concat("http://www.wikidata.org/wiki/",?wd)) as ?wikidata)
?euLabel (group_concat(distinct str(?euAltLabel);SEPARATOR="; ") as ?euAltLabels)
?euDef ?eusLex_eskuz ?testuingurua ?agertokia
?esLabel (group_concat(distinct str(?esAltLabel);SEPARATOR="; ") as ?esAltLabels)  
?esDef
?enLabel (group_concat(distinct str(?enAltLabel);SEPARATOR="; ") as ?enAltLabels)  
?enDef
where {
  ?concept eusdp:P6 euswb:Q3766;
           eusdp:P1 ?wd.
  optional{?concept eusp:P8 ?eusLex_st. ?eusLex_st eusps:P8 ?eusLex_eskuz.
  optional{?eusLex_st euspq:P10 ?testuingurua.}
  optional{?eusLex_st euspq:P11 ?agertokia.}}
  optional{?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu")}
  optional{?concept skos:altLabel ?euAltLabel. filter(lang(?euAltLabel)="eu")}
  optional{?concept schema:description ?euDef. filter(lang(?euDef)="eu")}
  optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
  optional{?concept skos:altLabel ?esAltLabel. filter(lang(?esAltLabel)="es")}
  optional{?concept schema:description ?esDef. filter(lang(?esDef)="es")}
  optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
  optional{?concept skos:altLabel ?enAltLabel. filter(lang(?enAltLabel)="en")}
  optional{?concept schema:description ?enDef. filter(lang(?enDef)="en")}
  
 } group by ?concept ?wd ?euLabel ?euAltLabels ?euDef ?eusLex_eskuz ?testuingurua ?agertokia ?esLabel ?esAltLabels ?esDef ?enLabel ?enAltLabels ?enDef
order by ?euLabel

Try it!


Eskuz gehitutako euskarazko lexikalizazioak

#title:"Kolore Izenak" eskemako kontzeptuak hiru hizkuntzetan (euskarazko izena eskuz gehitu den sarrerak)

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>
PREFIX eusno: <https://eusterm.wikibase.cloud/prop/novalue/>

select ?concept (iri(concat("http://www.wikidata.org/wiki/",?wd)) as ?wikidata)
?euLabel (group_concat(distinct str(?euAltLabel);SEPARATOR="; ") as ?euAltLabels)
?euDef ?eusLex_eskuz ?testuingurua ?agertokia
?esLabel (group_concat(distinct str(?esAltLabel);SEPARATOR="; ") as ?esAltLabels)  
?esDef
?enLabel (group_concat(distinct str(?enAltLabel);SEPARATOR="; ") as ?enAltLabels)  
?enDef
where {
  ?concept eusdp:P6 euswb:Q3766;
           eusdp:P1 ?wd.
  ?concept eusp:P8 ?eusLex_st. ?eusLex_st eusps:P8 ?eusLex_eskuz. 
           optional{?eusLex_st euspq:P10 ?testu.
                   bind(concat(substr(?testu,1,36),"...") as ?testuingurua)}          
          optional{?eusLex_st euspq:P11 ?ref. 
                   bind(concat(substr(?ref,1,36),"...") as ?agertokia)}
  optional{?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu")}
  optional{?concept skos:altLabel ?euAltLabel. filter(lang(?euAltLabel)="eu")}
  optional{?concept schema:description ?euDef. filter(lang(?euDef)="eu")}
  optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
  optional{?concept skos:altLabel ?esAltLabel. filter(lang(?esAltLabel)="es")}
  optional{?concept schema:description ?esDef. filter(lang(?esDef)="es")}
  optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
  optional{?concept skos:altLabel ?enAltLabel. filter(lang(?enAltLabel)="en")}
  optional{?concept schema:description ?enDef. filter(lang(?enDef)="en")}
  
 } group by ?concept ?wd ?euLabel ?euAltLabels ?euDef ?eusLex_eskuz ?testuingurua ?agertokia ?esLabel ?esAltLabels ?esDef ?enLabel ?enAltLabels ?enDef
order by ?euLabel

Try it!


Koloreen azpi-klaseak

#defaultView:Graph
#title:"Koloreak" eskemako kontzeptuak

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>

select ?subject ?subjectLabel ?edge ?object ?objectLabel
where { 
  ?object eusdp:P6 euswb:Q3766.
   ?subject ?edge ?object.
  ?subject rdfs:label ?subjectLabel. filter(lang(?subjectLabel)="eu")
  # ?object rdfs:label ?objectLabel. filter(lang(?objectLabel)="eu")
  values ?prop { eusdp:P3 eusdp:P4 }
 # bind("kind of" as ?edgeLabel)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "eu". }
}

Try it!

Kolore-izenak Eustermen eta Wikidatan

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>

select ?concept  ?wikidata_item
?euLabel (group_concat(distinct str(?euAltLabel);SEPARATOR="; ") as ?euAltLabels)  
?esLabel (group_concat(distinct str(?esAltLabel);SEPARATOR="; ") as ?esAltLabels)  
?enLabel (group_concat(distinct str(?enAltLabel);SEPARATOR="; ") as ?enAltLabels)  
?frLabel (group_concat(distinct str(?frAltLabel);SEPARATOR="; ") as ?frAltLabels)  
?wikidata_enlabel ?wikidata_eulabel ?wikidata_altLabels ?wikidata_def
where {
  ?concept eusdp:P6 euswb:Q3766.   
 
  ?concept eusdp:P1 ?wd. bind (iri(concat(str(wd:),?wd)) as ?wikidata_item)
  ?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu")
  optional{?concept skos:altLabel ?euAltLabel. filter(lang(?euAltLabel)="eu")}
  optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
  optional{?concept skos:altLabel ?esAltLabel. filter(lang(?esAltLabel)="es")}
  optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
  optional{?concept skos:altLabel ?enAltLabel. filter(lang(?enAltLabel)="en")}
  optional{?concept rdfs:label ?frLabel. filter(lang(?frLabel)="fr")}
  optional{?concept skos:altLabel ?frAltLabel. filter(lang(?frAltLabel)="fr")}
  
   SERVICE <https://query.wikidata.org/sparql> { select ?wikidata_item ?wikidata_enlabel ?wikidata_eulabel (group_concat(distinct str(?wikidata_altLabel);SEPARATOR="; ") as ?wikidata_altLabels) ?wikidata_def
  WHERE { 
   
   ?wikidata_item rdfs:label ?wikidata_enlabel. filter(lang(?wikidata_enlabel)="en")
    optional {?wikidata_item rdfs:label ?wikidata_eulabel. filter(lang(?wikidata_eulabel)="eu")} 
       optional {?wikidata_item schema:description ?wikidata_def. filter(lang(?wikidata_def)="eu")} 
       optional {?wikidata_item skos:altLabel ?wikidata_altLabel. filter(lang(?wikidata_altLabel)="eu")}
                         } group by ?wikidata_item ?wikidata_enlabel ?wikidata_eulabel ?wikidata_altLabels ?wikidata_def}
  
 } group by ?concept  ?wikidata_item ?euLabel ?euAltLabels ?esLabel ?esAltLabels ?enLabel ?enAltLabels ?frLabel ?frAltLabels ?wikidata_enlabel ?wikidata_eulabel ?wikidata_altLabels ?wikidata_def
order by ?esLabel

Try it!

Retrieved from "https://eusterm.wikibase.cloud/w/index.php?title=Kolore_Izenak&oldid=27180"