Igeriketa

From eusterm

Igeriketa, kontzeptu-eskema bat

Wikidata iturriak

Ondorengo Wikipedia artikuluetatik erauzi egin dira terminoak (Wikipedia barruko lotura urdinak)

Eskema deskribatzen duen entitatea

Proiektuaren deskribapena

Egilea

Garazi Zapirain Zubiaurre

Metodologia

Proiektu honen ardatza UZEI igeriketa hiztegia da. Bertan dauden terminoak wikipedian daudenekin alderatu ditut, wikidatan Uzeiko termino bakoitzaren Q zenbakiaren baliokidea bilatuz. Horrela, taula bikoitza sortu dut zutabea batean Uzeiko Q zenbakia, ondoren wikidatakoa eta hirugarren batean bi Q zenbakien arteko erlazioa zein den (exactmatch, closematch edo hasisintance). Lan prozesua hiztegiko definizio zein terminoekin egin da.

Emaitzak

Lanaren emaitzak behean ikus daitezkeen hainbat galdeketa dira: -Instance of moduko erlazioak dituzten terminoen taula -Bi eskemetan ageri diren kontzeptuena - Bi eskemetako terminoen euskarazko lexikalizazioa - Bi eskemetako terminoen euskarazko definizioak

Euskarazko lexikalizazioen kasuan ez da arazorik egon eta ez ditut sortu behar izan jadanik denak lexikalizatuak zeudelako. Kontzeptu guztiak ez dira bi eskemetan exactmatch moduan ageri eta horregatik sortua dago instance of galdeketa; termino gehienen erlazioa hau delako. Definizio zein kontzeptuenean emaitzen lorpenean bi etapa moduko egon dira: behin Qzenbaki guztiak izanda atera den taula eta definitiboa, soberan zeudenak edo definizio egokirik ez zutenak kendu ondorengoa.

Datu-base galdeketak

Wikidatatik hartutako eskema ikusteko galdeketa

Galdeketa honen bitartez, eskemako kontzeptuak eta erlazioak ikusi. Euskarazko lexikalizaziorik ez dutenak ez dira agertuko! 

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>
PREFIX eusno: <https://eusterm.wikibase.cloud/prop/novalue/>

select ?concept ?conceptLabel ?edgeLabel ?concept2 ?concept2Label where {
  ?concept eusdp:P6 euswb:Q205; rdfs:label ?conceptLabel. filter(lang(?conceptLabel)="eu")
  optional {?concept ?rel ?concept2. values ?rel {eusdp:P3 eusdp:P4 eusdp:P5}
            ?edge wikibase:directClaim ?rel ; rdfs:label ?edgeLabel . filter(lang(?edgeLabel)="eu")
            ?concept2 rdfs:label ?concept2Label. filter(lang(?concept2Label)="eu")
           }
 }

Try it!

UZEItik hartutako eskema ikusteko galdeketa

Galdeketa honen bitartez, eskemako kontzeptuak eta erlazioak ikusi (part of, instance of, subclass of) 

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>
PREFIX eusno: <https://eusterm.wikibase.cloud/prop/novalue/>

select ?concept ?conceptLabel ?edgeLabel ?concept2 ?concept2Label where {
  ?concept eusdp:P6 euswb:Q198; rdfs:label ?conceptLabel. filter(lang(?conceptLabel)="eu")
  optional {?concept ?rel ?concept2. values ?rel {eusdp:P3 eusdp:P4 eusdp:P5}
            ?edge wikibase:directClaim ?rel ; rdfs:label ?edgeLabel . filter(lang(?edgeLabel)="eu")
            ?concept2 rdfs:label ?concept2Label. filter(lang(?concept2Label)="eu")
           }
 }

Try it!

Bi eskemetan dauden kontzeptuak ikusteko galdeketa

Galdeketa honen bitartez, bi eskemetan agertzen direnen erlazioak ikusi (part of, instance of, subclass of) 

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>
PREFIX eusno: <https://eusterm.wikibase.cloud/prop/novalue/>

select ?concept ?conceptLabel (group_concat(?altLabel;SEPARATOR="; ") as ?alternativeLabels) ?uzeilex ?wikidata where {
  ?concept eusdp:P6 euswb:Q198; eusdp:P6 euswb:Q205; rdfs:label ?conceptLabel. filter(lang(?conceptLabel)="eu")
  optional {?concept skos:altLabel ?altLabel. filter(lang(?altLabel)="eu")}
  optional {?concept eusdp:P8 ?uzeilex.}  
  optional {?concept eusdp:P1 ?wikidata.}
 } group by ?concept ?conceptLabel ?alternativeLabels ?uzeilex ?wikidata

Try it!


Instance-of erlazioak

Galdeketa honen bitartez, ikusi zer "instance-of" erlazio dauden bi eskematako terminoen artean: 

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>
PREFIX eusno: <https://eusterm.wikibase.cloud/prop/novalue/>

select ?concept ?conceptLabel ?edgeLabel ?concept2 ?concept2Label ?source where { values ?schemes {euswb:Q198 euswb:Q205}
  ?concept eusdp:P6 ?schemes.
  ?concept eusp:P5 ?statement. ?statement eusps:P5 ?concept2.
  #  filter not exists {?statement prov:wasDerivedFrom [euspr:P1 ?source].} 
            bind("honen instantzia" as ?edgeLabel)
           # ?concept2 eusdp:P6 ?schemes.
            SERVICE wikibase:label { bd:serviceParam wikibase:language "eu,en". }
  }

Try it!

Euskarazko lexikalizazioa falta zaien kontzeptuak (Wikidata)

Galdeketa honen bitartez, euskarazko lexikalizaziorik ez dutenak ikusi: 

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>
PREFIX eusno: <https://eusterm.wikibase.cloud/prop/novalue/>

select ?concept (group_concat(str(?conceptLabel);SEPARATOR="; ") as ?labels)  where {
  ?concept eusdp:P6 euswb:Q205. filter not exists { ?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu") }
  ?concept rdfs:label ?conceptLabel.
 } group by ?concept ?labels

Try it!


Euskara-Gaztelera-Ingelesa Hiztegia (UZEI)

Eskema honetako kontzeptuan hiztegi hirueleduna ikusteko, erabili galdeketa hau. 

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>
PREFIX eusno: <https://eusterm.wikibase.cloud/prop/novalue/>

select ?concept 
?euLabel (group_concat(distinct str(?euAltLabel);SEPARATOR="; ") as ?euAltLabels)  
?esLabel (group_concat(distinct str(?esAltLabel);SEPARATOR="; ") as ?esAltLabels)  
?enLabel (group_concat(distinct str(?enAltLabel);SEPARATOR="; ") as ?enAltLabels)  
where {
  ?concept eusdp:P6 euswb:Q198. 
  optional{?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu")}
  optional{?concept skos:altLabel ?euAltLabel. filter(lang(?euAltLabel)="eu")}
  optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
  optional{?concept skos:altLabel ?esAltLabel. filter(lang(?esAltLabel)="es")}
  optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
  optional{?concept skos:altLabel ?enAltLabel. filter(lang(?enAltLabel)="en")}
  
 } group by ?concept ?euLabel ?euAltLabels ?esLabel ?esAltLabels ?enLabel ?enAltLabels
order by ?euLabel

Try it!


UZEI eta WIKIDATA-ko kontzeptu-etiketak

Ikusteko euskarazko zer etiketa dauden Eusterm-en (UZEI-ko kontzeptuak) eta Wikidatan (haiekin "exactMatch" gisa lerrokatutakoak), erabili galdeketa hau. 

PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>
PREFIX eusno: <https://eusterm.wikibase.cloud/prop/novalue/>

select ?concept ?eusterm_prefLabel
(group_concat(distinct str(?euAltLabel);SEPARATOR="; ") as ?eusterm_altLabels)  
# ?esLabel (group_concat(distinct str(?esAltLabel);SEPARATOR="; ") as ?esAltLabels)  
# ?enLabel (group_concat(distinct str(?enAltLabel);SEPARATOR="; ") as ?enAltLabels)  
?wd_uri ?wd_enPrefLabel ?wd_prefLabel ?wd_altLabels
where { #bind("Q5" as ?wikidata)
?concept eusdp:P6 euswb:Q198; eusdp:P1 ?wikidata ; rdfs:label ?eusterm_prefLabel . filter(lang(?eusterm_prefLabel)="eu") 

#   optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
#   optional{?concept skos:altLabel ?esAltLabel. filter(lang(?esAltLabel)="es")}
#   optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
#   optional{?concept skos:altLabel ?enAltLabel. filter(lang(?enAltLabel)="en")}

bind(iri(concat("http://www.wikidata.org/entity/",?wikidata)) as ?wd_uri)
SERVICE <https://query.wikidata.org/sparql> {    
select ?wd_uri ?wd_enPrefLabel ?wd_prefLabel (group_concat(distinct str(?wd_altLabel);SEPARATOR="; ") as ?wd_altLabels)  
WHERE { ?wd_uri rdfs:label ?wd_enPrefLabel. filter(lang(?wd_enPrefLabel)="en")
  optional{?wd_uri rdfs:label ?wd_prefLabel. filter(lang(?wd_prefLabel)="eu")}
  optional{?wd_uri skos:altLabel ?wd_altLabel. filter(lang(?wd_altLabel)="eu")}
} group by ?wd_uri ?wd_enPrefLabel ?wd_prefLabel ?wd_altLabels }
   
  optional{?concept skos:altLabel ?euAltLabel. filter(lang(?euAltLabel)="eu")}
     
 } group by ?concept ?eusterm_prefLabel
 ?eusterm_altLabels
?wd_uri ?wd_enPrefLabel ?wd_prefLabel ?wd_altLabels
order by ?eusterm_prefLabel

Try it!

Euskarazko definizioak Eustermen eta Wikidatan

Ikusteko, zer definizio kontzeptu bakoitzak Eusterm-eko eskeman eta Wikidatan, erabili galdeketa hau. Wikidatako definizioa Eusterm-eko definizioaz ordeztea da ideia. 

PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>
PREFIX eusno: <https://eusterm.wikibase.cloud/prop/novalue/>

select ?concept ?eusterm_prefLabel ?eusterm_def
?wd_uri ?wd_enPrefLabel ?wd_euPrefLabel ?wd_def
where { 
?concept eusdp:P6 euswb:Q198; eusdp:P1 ?wikidata ; rdfs:label ?eusterm_prefLabel . filter(lang(?eusterm_prefLabel)="eu") 
bind(iri(concat("http://www.wikidata.org/entity/",?wikidata)) as ?wd_uri)
SERVICE <https://query.wikidata.org/sparql> {    
select ?wd_uri ?wd_enPrefLabel ?wd_euPrefLabel ?wd_def
WHERE { ?wd_uri rdfs:label ?wd_enPrefLabel. filter(lang(?wd_enPrefLabel)="en")
  optional{?wd_uri rdfs:label ?wd_euPrefLabel. filter(lang(?wd_euPrefLabel)="eu")}
  optional{?wd_uri schema:description ?wd_def. filter(lang(?wd_def)="eu")}
} group by ?wd_uri ?wd_enPrefLabel ?wd_euPrefLabel ?wd_def }
 optional{?concept schema:description ?eusterm_def. filter(lang(?eusterm_def)="eu")}
} group by ?concept ?eusterm_prefLabel ?eusterm_def
?wd_uri ?wd_enPrefLabel ?wd_euPrefLabel ?wd_def
order by ?eusterm_prefLabel

Try it!

Wikidatan idatzi izana

Proiektu honen emaitza bat Wikidatan 70 lexikalizazio eta definizio idatzi izana da.

Retrieved from "https://eusterm.wikibase.cloud/w/index.php?title=Igeriketa&oldid=9382"