Eskubaloia

From eusterm

Lanaren progresioa

Egilea: Elene Basurco

Nire proiektuaren abiapuntua UZEI Eskubaloia hiztegia izango da.

Eskubaloia aukeratu dut gai gisa asko gustatzen eta txikitatik jokatu dudan kirola baita. Nire hasierako ideia Wikipediako Handball artikuluan agertzen ziren definizio eta kontzeptuak euskaratzea zen, baina irakasleak klasean esan dit UZEIko hiztegian Eskubaloiarekin lotutako atal bat dagoela 4 hizkuntzetan (euskara, gaztelania, ingelesa, eta frantsesez). Beraz, pentsatu dut lan polit bat sortu dezakedala. Orduan, irakasleak nire eustermeko orrian sartzeko, Eskubaloia-hiztegien edukia erauzi dit. Nire lehenengo lana beraz, eskubaloi arloko kontzeptuen datu-basea CSV moduan deskargatzea izan da.

Behin CSV-a deskargatu dudala, dokumentua ireki eta nire zeregina guztira zenbat kontzeptu dauden jakitea izan da. Bestalde irakasleak ariketa bat proposatu dit. Ariketa horren helburua hizkuntza bakoitzean zenbat definizio eta kontzeptu dauden jakitea izan da. Hauek izan dira emaitzak: Uzei-ko hiztegiak guztira eskubaloiaren arloarekin lotutako 453 kontzeptu ditu. Kontzeptuei dagokienez, euskaraz 585 daude, gaztelanieraz 556, ingelesez 388 eta frantsesez 457. Definizioen aldetik, euskaraz 422 definizio daude, beste hiru hizkuntzetan ordea, ez da definiziorik agertzen.

Emaitza horiek jakin eta gero, Open Refine deituriko aplikazioa erabili dut Wikidatan agertzen ziren definizio eta kontzeptuekin alderatzeko eta nire helburua beraz, lau hizkuntzetan agertzen diren definizio eta kontzeptuak Wikidatan agertzen direnekin lotura egokia duten ikustea izan da. Harrituta geratu nahiz zeren pentsatzen nuen match ugari egingo nituela eta ordea, emaitzak hauek izan dira: 109 match. Kasu batzuetan gertatu zait, match-a ez zela guztiz egokia eta beraz, deuseztatu behar izan dut.

Behin match guztiak eginda, nire hurrengo betebeharra Q zenbakiak errenkada guztietan berdinak diren ikustea izan da. Kasu gehienetan, Q zenbakiak berdinak izan dira, baina pare bat kasuetan, Q zenbaki desberdinak ere aurkitu ditut. Kasu horietan gertatzen dena da lau hizkuntzetan agertzen diren kontzeptu eta definizioen lotura ezberdinak direla beraz, definizio eta kontzeptu biak irakurri eta alderatu egin ditut bien artean egokiena dena hautatzeko. Behin Q zenbaki guztiak berdinak izan direnean eta behin eta berriz errepasatu eta gero akatsik ez dagoela ziurtatzeko, irakasleari bidali dizkiot emaitzak.

Behin hori guztia eginda, irakasleak beste ideia bat eman dit, asko gustatu zait eta beraz, bere ideia gauzatu dut. 109 kontzeptu eta definizoei argazkia topatzea eta jartzea izan da nire hurrengo betebeharra. Argazkien bidez, definizioak eta kontzeptuak hobeto eta argiago ulertu ditzakegu. Wikimedia Commons erabili dut horretarako. Hauek izan dira emaitzak: 109 definizio eta kontzeptuetatik, 50rrek daramate argazkia. Uste dut emaitza onak lortu ditudala, azken finean, definizio eta kontzeptu erdiek dute argazki adierazgarria eta.

Behin betebehar hori amaituta, irakasleari adierazi diot nire helburu nagusia gaztelania, ingeles eta frantseseko definizioetan ageri diren hutsuneak betetzea dela. Horretarako, "Hiztegietako Definizioak" atalera joan naiz eta hizkuntza guztietan agertzen ziren hutsuneak betetzen joan naiz. Gehienetan, euskarazko definizioa zegoen eta beraz, hortik abiatu naiz beste hizkuntzako hutsuneak bete ahal izateko. Emaitzak hauek izan dira: orain gaztelaniaz, 430 definizio daude, ingelesez, 324 eta frantseses, 374. Kasu batzuetan, kontzeptuak soilik ageri dira eta ez da hizkuntza bakar batean definiziorik agertzen, beraz, horiek ez ditut bete.

Horrez gain, definizio guztiak Wikidatako estilora moldatu ditut, definizio bukaeran agertzen diren puntuak kendu, letra larriak ezabatu eta definizio luzeak laburtu ditut, horietako askok zuten informazio gehigarria laburtuz.

Laburbilduz, nire eginbeharrak Q loturak errenkada guztietan zuzenak diren ikustea, definizio eta kontzeptuak argazkiei esleitzea, definizioak Widikata estilora egokitzea eta kontzeptu eta terminologia aldetik zeuden hutsuneak betetzea izan dira.

Beraz, lana amaitutzat ematen dut eta hurrengo eta azken helburua orrialde honetan aipatu eta egin dudan guztia Wikidatara bidaltzea izango da.

ZER BIDALI WIKIDATARA?

  • Match-en bidez egin ditudan 109 kontzeptuak bidali.
  • 109 kontzeptu horietatik 50ek duten argazkiak Wikidatara bidali. Wikidatan argazkiak agertzen badira matxakatu.
  • Hiztegietako Definizioak atalean agertzen diren ingeles, gaztelania eta frantseseko lexikalizazi eta definizioak Wikidatara bidali. Wikidatan beste lexikalizazio edo definizio batzuk agertzen badira horiek matxakatu egin behar dira.
  • Hiztegietako Definizioetan agertzen den euskarako lexikalizazio eta definizioak bidali, Wikidatan definizio edo/eta kontzeptu bat agertzen bada hura matxakatuz.

"Eskubaloia" kontzeptu-eskema deskribatzen duen entitatea

Eskema honen kontzeptuak Q11455 entitateari lotuta daude.

Datu-base galdeketak

Euskara-Gaztelera-Frantsesa-Ingelesa Hiztegia

Eskema honetako kontzeptuan hiztegi laueleduna ikusteko, erabili galdeketa hau. "uzeid" dutenak UZEI-ko "Eskubaloia Hiztegia" lanetik datoz. 

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>

select ?concept ?uzeid
?euLabel (group_concat(distinct str(?euAltLabel);SEPARATOR="; ") as ?euAltLabels)  
?esLabel (group_concat(distinct str(?esAltLabel);SEPARATOR="; ") as ?esAltLabels)  
?enLabel (group_concat(distinct str(?enAltLabel);SEPARATOR="; ") as ?enAltLabels)  
?frLabel (group_concat(distinct str(?frAltLabel);SEPARATOR="; ") as ?frAltLabels)  
where {
  ?concept eusdp:P6 euswb:Q11455. 
  optional{?concept eusdp:P15 ?uzei_id. bind(xsd:integer(strafter(?uzei_id,"Eskubaloia_")) as ?uzeid)}
  optional{?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu")}
  optional{?concept skos:altLabel ?euAltLabel. filter(lang(?euAltLabel)="eu")}
  optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
  optional{?concept skos:altLabel ?esAltLabel. filter(lang(?esAltLabel)="es")}
  optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
  optional{?concept skos:altLabel ?enAltLabel. filter(lang(?enAltLabel)="en")}
  optional{?concept rdfs:label ?frLabel. filter(lang(?frLabel)="fr")}
  optional{?concept skos:altLabel ?frAltLabel. filter(lang(?frAltLabel)="fr")}
  
 } group by ?concept ?uzeid ?euLabel ?euAltLabels ?esLabel ?esAltLabels ?enLabel ?enAltLabels ?frLabel ?frAltLabels
order by ?uzeid

Try it!

Hiztegitako definizioak

Eskema honetan agertzen diren definizioak ikusteko, erabili galdeketa hau. "uzeid" dutenak UZEI-ko "Eskubaloia Hiztegia" lanetik datoz. 

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>

select distinct ?concept ?uzeid
?euLabel ?euDescription
?esLabel ?esDescription
?enLabel ?enDescription 
?frLabel ?frDescription
where {
  ?concept eusdp:P6 euswb:Q11455. 
  optional{?concept eusdp:P15 ?uzei_id. bind(xsd:integer(strafter(?uzei_id,"Eskubaloia_")) as ?uzeid)}
  optional{?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu")}
  optional{?concept schema:description ?euDescription. filter(lang(?euDescription)="eu")}
  optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
  optional{?concept schema:description ?esDescription. filter(lang(?esDescription)="es")}
  optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
  optional{?concept schema:description ?enDescription. filter(lang(?enDescription)="en")}
  optional{?concept rdfs:label ?frLabel. filter(lang(?frLabel)="fr")}
  optional{?concept schema:description ?frDescription. filter(lang(?frDescription)="fr")}
  
 } 
order by ?uzeid

Try it!


Hiztegiko kontzeptuak, arloka antolatuta

Galdeketa honek grafo itxurako bisualizazio batera darama. 

#defaultView:Graph
PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>

select * where {

  ?concept eusdp:P6 euswb:Q11455. 
  ?concept rdfs:label ?conceptLabel. filter(lang(?conceptLabel)="eu")
  ?concept eusdp:P166 ?arlo.
  ?arlo rdfs:label ?arloLabel. filter(lang(?arloLabel)="eu")
  
 } order by ?arlo

Try it!

Hiztegiak dituen irudiak

Galdeketa honek "Eskubaloia" eskemako irudiak erakusten ditu. 

#defaultView:ImageGrid
PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>

select * where {

  ?concept eusdp:P6 euswb:Q11455. 
  ?concept rdfs:label ?conceptLabel. filter(lang(?conceptLabel)="eu")
  ?concept eusdp:P166 ?arlo.
  ?arlo rdfs:label ?arloLabel. filter(lang(?arloLabel)="eu")
  ?concept eusdp:P169 ?irudia.
  
 } order by ?arlo

Try it!

Galdeketa honek erakusten du Wikidatarekin lerrokatutako kontzeptuetatik zeintzuk irudia duten, eta zeintzuk ez. 

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>

select * where {

  ?concept eusdp:P6 euswb:Q11455; eusdp:P1 ?wikidata.
  ?concept rdfs:label ?conceptLabel. filter(lang(?conceptLabel)="eu")
  ?concept eusdp:P166 ?arlo.
  ?arlo rdfs:label ?arloLabel. filter(lang(?arloLabel)="eu")
  optional{?concept eusdp:P169 ?irudia.}
  
 } order by ?arlo ?conceptLabel

Try it!

Wikidatarekin lotutako kontzeptuak

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>

select ?concept ?wikidata_item
?euLabel (group_concat(distinct str(?euAltLabel);SEPARATOR="; ") as ?euAltLabels)
?euDef
?esDef
?enDef
?wikidata_label ?wikidata_altLabels ?wikidata_def ?wikidata_enLabel ?wikidata_enDef ?wikidata_esLabel ?wikidata_esDef
where {
  ?concept eusdp:P6 euswb:Q11455.
  ?concept eusdp:P1 ?wd. bind (iri(concat(str(wd:),?wd)) as ?wikidata_item)
  optional{?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu")}
  optional{?concept skos:altLabel ?euAltLabel. filter(lang(?euAltLabel)="eu")}
  optional{?concept schema:description ?euDef. filter(lang(?euDef)="eu")}
  optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
  optional{?concept schema:description ?esDef. filter(lang(?esDef)="es")}
  optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
  optional{?concept schema:description ?enDef. filter(lang(?enDef)="en")}
  
  SERVICE <https://query.wikidata.org/sparql> { select ?wikidata_item ?wikidata_label (group_concat(distinct str(?wikidata_altLabel);SEPARATOR="; ") as ?wikidata_altLabels) ?wikidata_def ?wikidata_enLabel ?wikidata_enDef ?wikidata_esLabel ?wikidata_esDef
  WHERE { 
   ?wikidata_item rdfs:label ?wikidata_enLabel. filter(lang(?wikidata_enLabel)="en")
       optional {?wikidata_item rdfs:label ?wikidata_label. filter(lang(?wikidata_label)="eu")}
       optional {?wikidata_item schema:description ?wikidata_def. filter(lang(?wikidata_def)="eu")} 
       optional {?wikidata_item skos:altLabel ?wikidata_altLabel. filter(lang(?wikidata_altLabel)="eu")}
       optional{?wikidata_item schema:description ?wikidata_enDef. filter(lang(?wikidata_enDef)="en")}
       optional{?wikidata_item rdfs:label ?wikidata_esLabel. filter(lang(?wikidata_esLabel)="es")}
       optional{?wikidata_item schema:description ?wikidata_esDef. filter(lang(?wikidata_esDef)="es")}
                        } group by ?wikidata_item ?wikidata_label ?wikidata_altLabels ?wikidata_def ?wikidata_enLabel ?wikidata_enDef ?wikidata_esLabel ?wikidata_esDef
  }
  
 } group by ?concept ?wikidata_item ?euLabel ?euAltLabels ?euDef ?esLabel ?esAltLabels ?esDef ?enLabel ?enAltLabels ?enDef ?sareak ?wikidata_label ?wikidata_altLabels ?wikidata_def ?wikidata_enLabel ?wikidata_enDef ?wikidata_esLabel ?wikidata_esDef
order by lcase(?euLabel)

Try it!

Retrieved from "https://eusterm.wikibase.cloud/w/index.php?title=Eskubaloia&oldid=50175"