Emakumeen Aurkako Indarkeria

Emakumeen Aurkako Indarkeria, kontzeptu-eskema bat

Egilea: Lilia Astorkia

Kontzeptu-eskema hau errepresentatzen duen entitatea: Q6745

Abiapuntua

UZEI-ko "Feminismoa" hiztegitik, "emakumeen aurkako indarkeria" ataleko terminoak datu base honetan sartu ditugu.

Helburua eta Metodologia

(Zer lortu nahi dugu, eta nola)

SPARQL

Euskara-Gaztelera-Frantsesa-Ingelesa Hiztegia

Eskema honetako kontzeptuan hiztegi laueleduna ikusteko, erabili galdeketa hau. "uzeid" dutenak UZEI-ko "Feminismoa Hiztegia" lanetik datoz. "Wikidata" dutenak Wikidatarekin lerrokatuta daude.

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>

select ?concept ?uzeid (iri(concat("http://www.wikidata.org/entity/",?wd)) as ?wikidata)
?euLabel (group_concat(distinct str(?euAltLabel);SEPARATOR="; ") as ?euAltLabels)  
?esLabel (group_concat(distinct str(?esAltLabel);SEPARATOR="; ") as ?esAltLabels)  
?enLabel (group_concat(distinct str(?enAltLabel);SEPARATOR="; ") as ?enAltLabels)  
?frLabel (group_concat(distinct str(?frAltLabel);SEPARATOR="; ") as ?frAltLabels)  
where {
  ?concept eusdp:P6 euswb:Q6745. 
  optional{?concept eusdp:P1 ?wd.}
  optional{?concept eusdp:P15 ?uzei_id. bind(xsd:integer(strafter(?uzei_id,"feminismoa_")) as ?uzeid)}
  optional{?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu")}
  optional{?concept skos:altLabel ?euAltLabel. filter(lang(?euAltLabel)="eu")}
  optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
  optional{?concept skos:altLabel ?esAltLabel. filter(lang(?esAltLabel)="es")}
  optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
  optional{?concept skos:altLabel ?enAltLabel. filter(lang(?enAltLabel)="en")}
  optional{?concept rdfs:label ?frLabel. filter(lang(?frLabel)="fr")}
  optional{?concept skos:altLabel ?frAltLabel. filter(lang(?frAltLabel)="fr")}
  
 } group by ?concept ?uzeid ?wd ?euLabel ?euAltLabels ?esLabel ?esAltLabels ?enLabel ?enAltLabels ?frLabel ?frAltLabels
order by ?uzeid

Try it!

Wikidatan topatutako UZEI kontzeptuak

Hemen UZEI eta Wikidata identifikatzaile biak dituztenak agertuko dira:

#title:Indarkeria kontzeptuak: Eustermen eta Wikidatan dituzten lexikalizazio hobetsiekin eta definizioekin
PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>

select ?eusterm_item ?wikidata_item ?uzeid ?eskuz_lex ?eskuz_def ?eusterm_label (group_concat(distinct str(?eusterm_altLabel);SEPARATOR="; ") as ?eusterm_altLabels) ?eusterm_def 
       ?wikidata_label ?wikidata_altLabels ?wikidata_def

where {
  ?eusterm_item eusdp:P6 euswb:Q6745;
           eusdp:P1 ?wd.
   bind (iri(concat(str(wd:),?wd)) as ?wikidata_item)
  optional{?eusterm_item eusdp:P15 ?uzei_id. bind(xsd:integer(strafter(?uzei_id,"feminismoa_")) as ?uzeid)}
  optional {?eusterm_item eusdp:P8 ?eskuz_lex.}
   optional {?eusterm_item eusdp:P13 ?eskuz_def.}
  optional {?eusterm_item rdfs:label ?eusterm_label. filter(lang(?eusterm_label)="eu")}
  optional {?eusterm_item skos:altLabel ?eusterm_altLabel. filter(lang(?eusterm_altLabel)="eu")}
  optional {?eusterm_item schema:description ?eusterm_def. filter(lang(?eusterm_def)="eu")}
  
  SERVICE <https://query.wikidata.org/sparql> { select ?wd ?wikidata_item ?wikidata_label (group_concat(distinct str(?wikidata_altLabel);SEPARATOR="; ") as ?wikidata_altLabels) ?wikidata_def
  WHERE { 
   
   ?wikidata_item rdfs:label ?wikidata_label. filter(lang(?wikidata_label)="eu")
       optional {?wikidata_item schema:description ?wikidata_def. filter(lang(?wikidata_def)="eu")} 
       optional {?wikidata_item skos:altLabel ?wikidata_altLabel. filter(lang(?wikidata_altLabel)="eu")}
                        } group by ?wd ?wikidata_item ?wikidata_label ?wikidata_altLabels ?wikidata_def
  }
 } group by ?eusterm_item ?wikidata_item ?uzeid ?eskuz_lex ?eskuz_def ?eusterm_label ?eusterm_altLabels ?eusterm_def ?wikidata_label ?wikidata_altLabels ?wikidata_def

Try it!