Elikadura portaeraren nahasmendua

ABIAPUNTUA: Naroa Ballarena naiz, eta nere laneko abiapuntua Wikipediako artikulu hau izango da: https://en.wikipedia.org/wiki/Eating_disorder

ZER EGIN DUT? Esan bezala, wikipediako artikulu hortatik abiatuz, urdinez zeuden terminoak hartu ditut. Behin horiek hartuta eta ez nituenak nahi (adb: pertsona izenak) kendu ondoren, 78 termino geratu zaizkit euskarazko lexikalizazio gabe, eta hauek gehitzen saiatu naiz. Hauen artean, 41 euskarazko lexikalizazio egitea lortu dut eta beste 37 termino ezin izan ditut euskaratu, batez ere informazio falta asko dagoelako gai honi buruz.

Ondoren, euskarazko definizioa falta duten kontzeptuei definizio bat gehitzea erabaki dut. Guztira, 101 terminok ez dute euskarazko definiziorik, eta nik horietako 76 terminori gehitu diet definizioa, hala ere, 30 ezin izan ditut definitu.

NOLA EGIN DUT? Astion aipatutako euskal lexikalizazioak hiztegi ezberdinetan bilatzen saiatun naiz; gehien erabili dudana euskalterm izan da; baina elhuyar, euskaltzaindia etab. ere oso lagungarriak izan dira. Baina dena ezta hain erraza izan, izan ere, askotan hiztegietan ez dut aurkitu nik euskaratu nahi nuen terminoaren euskal lexikalizazioa. Beraz, kasu hoietan, nik nolabaiteko euskal lexikalizazioa egin dut nire kontu, eta gero artikulu akademikoetan bilatu dut ea lortzen nuen informaziorik. Eta asko bilatu ostean, batzuenak aurkitu ditut. Nahiko lagungarria izan da baita ere medikuntza gaietan adituekin hitz egitea edo beraien materiala erabiltzea. Aipatzekoa da, behin definizioa topatu ondoren, garrantzitsuena eta denek ulertzeko modukoa dena hautatzea ongi dagoela, zerbait murritza baina esanguratsua izan behar baita, wikidatako estiloa jarraituz beti ere.

Definizioei dagokienez, wikipedia oso lagungarria izan da. Hor aurkitu dut gai askotako informazioa, beraz, hortik hartu ditut asko. Bestela, baita ere artikulu akademikoetan ere asko bilatu dut.

Bukatzeko, nire proiektuan jada zeuden eta nik egindako definizioak eta lexikalizazioak wikidatako formatuan jarri ditut, hau da nireak ongi ipini eta lehenagotik hor zeudenak zuzendu. Wikidatako estiloa jarraitzeko definizioak murriztu, punturik bazegoen kentzen saiatu, letra nagusiak ezabatu, aditz nagusiak ezabatu etab egin dut. Guztira 100 definizio zuzendu ditut.

ZAILTASUNAK: Zailtasun handiena medikuntza inguruan euskarazko informazioa edota terminologia oso urria denez, hasieratik euskal lexikalizazioa aurkitzea ez da batere lan erraza izan. Bestalde, badira interneten hainbat itzultzaile automatiko artikulu edota webgune bat edozein hizkuntzara itzultzen dutena, baina berez horiek emandako euskal lexikalizazioa ez da ofiziala, beraz kontuz ibili naiz iturriaren jatorria begiratzerakoan.

ONDORIOAK: Bukatzeko, konturatu naiz gai hauei buruz badagoen terminologia urriaz, eta baita adituekin edota ikasleekin hitz egitean, ondorioztatu dut arazo nahiko larria dela eta oso beharrezkoa dela terminologia honetan lan egitea.

WIKIDATARA BIDALTZEKO DATUAK: euskarazko lexikalizazioa falta duten kontzeptuak, euskarazko definizioak wikidatan eta eustermen eta egindako zuzenketa guztiak. Hau da, nik egindako GUZTIA.

Kontzeptu-eskemaren entitatea: Q12287

Eskema ikusteko galdeketa

Galdeketa honen bitartez, eskemako kontzeptuak eta erlazioak ikusi. Euskarazko lexikalizaziorik ez dutenak ez dira agertuko!

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>
PREFIX eusno: <https://eusterm.wikibase.cloud/prop/novalue/>

select ?concept ?conceptLabel ?edgeLabel ?concept2 ?concept2Label where {
  ?concept eusdp:P6 euswb:Q12287; rdfs:label ?conceptLabel. filter(lang(?conceptLabel)="eu")
  optional {?concept ?rel ?concept2. values ?rel {eusdp:P3 eusdp:P4 eusdp:P5}
            ?edge wikibase:directClaim ?rel ; rdfs:label ?edgeLabel . filter(lang(?edgeLabel)="eu")
            ?concept2 rdfs:label ?concept2Label. filter(lang(?concept2Label)="eu")
           }
 }

Try it!

Euskarazko lexikalizazioa falta zaien kontzeptuak

Galdeketa honen bitartez, euskarazko lexikalizaziorik ez dutenak ikusi:

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>
PREFIX eusno: <https://eusterm.wikibase.cloud/prop/novalue/>

select ?concept (group_concat(str(?conceptLabel);SEPARATOR="; ") as ?labels)  where {
  ?concept eusdp:P6 euswb:Q12287. filter not exists { ?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu") }
  ?concept rdfs:label ?conceptLabel.
 } group by ?concept ?labels

Try it!

Euskara-Gaztelera-Ingelesa Hiztegia

Eskema honetako kontzeptuan hiztegi hirueleduna ikusteko, erabili galdeketa hau.

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>
PREFIX eusno: <https://eusterm.wikibase.cloud/prop/novalue/>

select ?concept 
?euLabel (group_concat(distinct str(?euAltLabel);SEPARATOR="; ") as ?euAltLabels)  
?esLabel (group_concat(distinct str(?esAltLabel);SEPARATOR="; ") as ?esAltLabels)  
?enLabel (group_concat(distinct str(?enAltLabel);SEPARATOR="; ") as ?enAltLabels)  
where {
  ?concept eusdp:P6 euswb:Q12287. 
  optional{?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu")}
  optional{?concept skos:altLabel ?euAltLabel. filter(lang(?euAltLabel)="eu")}
  optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
  optional{?concept skos:altLabel ?esAltLabel. filter(lang(?esAltLabel)="es")}
  optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
  optional{?concept skos:altLabel ?enAltLabel. filter(lang(?enAltLabel)="en")}
  
 } group by ?concept ?euLabel ?euAltLabels ?esLabel ?esAltLabels ?enLabel ?enAltLabels
order by ?euLabel

Try it!

Euskarazko kontzeptu-etiketak Eustermen eta Wikidatan

Ikusteko, zer lexikalizazio dituen kontzeptu bakoitzak Eusterm-eko eskeman eta Wikidatan, erabili galdeketa hau. Wikidatako "prefLabel" eta "altLabel" Eusterm-eko etiketez ordeztea da ideia.

PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>
PREFIX eusno: <https://eusterm.wikibase.cloud/prop/novalue/>

select ?concept ?eusterm_prefLabel
(group_concat(distinct str(?euAltLabel);SEPARATOR="; ") as ?eusterm_altLabels)  
# ?esLabel (group_concat(distinct str(?esAltLabel);SEPARATOR="; ") as ?esAltLabels)  
# ?enLabel (group_concat(distinct str(?enAltLabel);SEPARATOR="; ") as ?enAltLabels)  
?wd_uri ?wd_enPrefLabel ?wd_prefLabel ?wd_altLabels
where { #bind("Q5" as ?wikidata)
?concept eusdp:P6 euswb:Q12287; eusdp:P1 ?wikidata ; rdfs:label ?eusterm_prefLabel . filter(lang(?eusterm_prefLabel)="eu") 

#   optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
#   optional{?concept skos:altLabel ?esAltLabel. filter(lang(?esAltLabel)="es")}
#   optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
#   optional{?concept skos:altLabel ?enAltLabel. filter(lang(?enAltLabel)="en")}

bind(iri(concat("http://www.wikidata.org/entity/",?wikidata)) as ?wd_uri)
SERVICE <https://query.wikidata.org/sparql> {    
select ?wd_uri ?wd_enPrefLabel ?wd_prefLabel (group_concat(distinct str(?wd_altLabel);SEPARATOR="; ") as ?wd_altLabels)  
WHERE { ?wd_uri rdfs:label ?wd_enPrefLabel. filter(lang(?wd_enPrefLabel)="en")
  optional{?wd_uri rdfs:label ?wd_prefLabel. filter(lang(?wd_prefLabel)="eu")}
  optional{?wd_uri skos:altLabel ?wd_altLabel. filter(lang(?wd_altLabel)="eu")}
} group by ?wd_uri ?wd_enPrefLabel ?wd_prefLabel ?wd_altLabels }
   
  optional{?concept skos:altLabel ?euAltLabel. filter(lang(?euAltLabel)="eu")}
     
 } group by ?concept ?eusterm_prefLabel
 ?eusterm_altLabels
?wd_uri ?wd_enPrefLabel ?wd_prefLabel ?wd_altLabels
order by ?eusterm_prefLabel

Try it!

Euskarazko definizioak Eustermen eta Wikidatan

Ikusteko, zer definizio kontzeptu bakoitzak Eusterm-eko eskeman eta Wikidatan, erabili galdeketa hau. Wikidatako definizioa Eusterm-eko definizioaz ordeztea da ideia.

PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>
PREFIX eusno: <https://eusterm.wikibase.cloud/prop/novalue/>

select ?concept ?eusterm_prefLabel ?eusterm_def
?wd_uri ?wd_enPrefLabel ?wd_euPrefLabel ?wd_def
where { 
?concept eusdp:P6 euswb:Q12287; eusdp:P1 ?wikidata ; rdfs:label ?eusterm_prefLabel . filter(lang(?eusterm_prefLabel)="eu") 
bind(iri(concat("http://www.wikidata.org/entity/",?wikidata)) as ?wd_uri)
SERVICE <https://query.wikidata.org/sparql> {    
select ?wd_uri ?wd_enPrefLabel ?wd_euPrefLabel ?wd_def
WHERE { ?wd_uri rdfs:label ?wd_enPrefLabel. filter(lang(?wd_enPrefLabel)="en")
  optional{?wd_uri rdfs:label ?wd_euPrefLabel. filter(lang(?wd_euPrefLabel)="eu")}
  optional{?wd_uri schema:description ?wd_def. filter(lang(?wd_def)="eu")}
} group by ?wd_uri ?wd_enPrefLabel ?wd_euPrefLabel ?wd_def }
 optional{?concept schema:description ?eusterm_def. filter(lang(?eusterm_def)="eu")}
} group by ?concept ?eusterm_prefLabel ?eusterm_def
?wd_uri ?wd_enPrefLabel ?wd_euPrefLabel ?wd_def
order by ?eusterm_prefLabel

Try it!

Kontzeptuen arteko oinarrizko erlazioak Eustermen

Galdeketa honek grafo itxurako bisualisazioa sortzen du, "instance of", "subclass of" eta "part of" erlazioen arabera.

#defaultView:Graph
PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>
PREFIX eusno: <https://eusterm.wikibase.cloud/prop/novalue/>

select ?concept ?conceptLabel ?concept2 ?concept2Label where {
  ?concept eusdp:P6 euswb:Q12287; rdfs:label ?conceptLabel. filter(lang(?conceptLabel)="eu")
  ?concept ?rel ?concept2. values ?rel {eusdp:P3 eusdp:P4 eusdp:P5}
            ?edge wikibase:directClaim ?rel.
            ?concept2 rdfs:label ?concept2Label. filter(lang(?concept2Label)="eu")
           
 } order by ?concept

Try it!