Astrologia

From eusterm

Astrologia, kontzeptu-eskema bat

Wikidata iturriak

Ondorengo Wikipedia artikuluetatik erauzi egin dira terminoak (Wikipedia barruko lotura urdinak)

Eskema deskribatzen duen entitatea

Proiektuaren deskribapena

Egilea

Itsasne Rego Barrenetxea

Iturria

Hainbat iturri erabili ditut. Wikipedian eta Wikidatan oinarritu naiz nagusiki loturak egiteko. Itzulpenak egiterakoan, Elhuyar eta Terminologue asko erabili ditut, baina astrologian erabiltzen den terminologia ez da asko erabili euskaraz, eta ondorioz, ez da agertzen hiztegi ofizialetan. Kasu hauetan, Google erabili dut jendeak sortutako blogetan zer erabiltzen den ikusteko. Kasu batzuetan ere Euskaltzaindiara jo dut.

Metodoa

Hasteko, Wikipediako Astrology and Astromomy artikulua hautatu dut. Ondoren, nire eskemaren parte izango ziren hitzak aukeratu ditut, eta hauek euskaratzen hasi naiz. Ez da lan erraza izan, ez delako gai honi buruz asko hitz egin euskaraz (horoskopoaren aspektu sinple eta ohikoenei buruz bai, baina badaud kontzeptu asko ez direnak oso ezagunak). Lehenengo, hitzak hiztegian edo terminologia bankuetan bilatu ditut. Gehienetan ez ditut aurkitu, beraz, Google-n bilatu ditut, eta jendeak idatzitako blogetan oinarritu naiz termino batzuetarako. Aipatutakoa egin eta gero itzulpenik gabe jarraitzen banuen, nik itzuli ditut terminoak hiztegien laguntzaz.

Kontzeptu batzuk aztertu behar izan ditut itzulpen egokia jartzeko. Zodiakoaren zeinuekin adibidez, arazoak eduki ditut. Izan ere, Wikipedian eta Euskaltzaindian lexikalizazio bat hobesten dela ikusi dut baina jendeak normalean erabiltzen ez dituen lexikalizazioak direla ikusi dut. Adibidez, "aquarius" da hobetsitako lexikalizazioa, baina hori latinezko izena da eta interneten jendearen erabilera aztertu ondoren, "akuario" aproposagoa dela ikusi dut. Hitz hau onartuta dago ere, baina bigarren motako lexikalizazio bezala. Kasu hauetan, hobetsitakoa etiketan jarri dut eta jendeak erabiltzen duena goitizenetan.

Azkenik, loturak sortu ditut kontzeptuen artean. Lotura gehienak astrologia moten artean eta ezaugarrien artean sortu ditut. Hala ere, pertsona izen asko nituenez, "lan eremua" izeneko propietatea sortu dut Wikidataren laguntzaz, horri esker pertsonak kontzeptuekin lotzeko.

Emaitza

Aipatutakoa egin ondoren, lan honen emaitza terminologia grafo bat da, euskarazko, gaztelerazko eta ingelerazko lexikalizazioak dituena.

Eskema ikusteko galdeketa

Galdeketa honen bitartez, eskemako kontzeptuak eta erlazioak ikusi. Euskarazko lexikalizaziorik ez dutenak ez dira agertuko! 

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>
PREFIX eusno: <https://eusterm.wikibase.cloud/prop/novalue/>

select ?concept ?conceptLabel ?edgeLabel ?concept2 ?concept2Label where {
  ?concept eusdp:P6 euswb:Q194; rdfs:label ?conceptLabel. filter(lang(?conceptLabel)="eu")
  optional {?concept ?rel ?concept2. values ?rel {eusdp:P3 eusdp:P4 eusdp:P5}
            ?edge wikibase:directClaim ?rel ; rdfs:label ?edgeLabel . filter(lang(?edgeLabel)="eu")
            ?concept2 rdfs:label ?concept2Label. filter(lang(?concept2Label)="eu")
           }
 }

Try it!


Euskarazko lexikalizazioa falta zaien kontzeptuak

Galdeketa honen bitartez, euskarazko lexikalizaziorik ez dutenak ikusi: 

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>
PREFIX eusno: <https://eusterm.wikibase.cloud/prop/novalue/>

select ?concept (group_concat(str(?conceptLabel);SEPARATOR="; ") as ?labels)  where {
  ?concept eusdp:P6 euswb:Q194. filter not exists { ?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu") }
  ?concept rdfs:label ?conceptLabel.
 } group by ?concept ?labels

Try it!


Euskara-Gaztelera-Ingelesa Hiztegia

Eskema honetako kontzeptuan hiztegi hirueleduna ikusteko, erabili galdeketa hau. 

PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>
PREFIX eusno: <https://eusterm.wikibase.cloud/prop/novalue/>

select ?concept 
?euLabel (group_concat(distinct str(?euAltLabel);SEPARATOR="; ") as ?euAltLabels)  
?esLabel (group_concat(distinct str(?esAltLabel);SEPARATOR="; ") as ?esAltLabels)  
?enLabel (group_concat(distinct str(?enAltLabel);SEPARATOR="; ") as ?enAltLabels)  
where {
  ?concept eusdp:P6 euswb:Q194. 
  optional{?concept rdfs:label ?euLabel. filter(lang(?euLabel)="eu")}
  optional{?concept skos:altLabel ?euAltLabel. filter(lang(?euAltLabel)="eu")}
  optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
  optional{?concept skos:altLabel ?esAltLabel. filter(lang(?esAltLabel)="es")}
  optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
  optional{?concept skos:altLabel ?enAltLabel. filter(lang(?enAltLabel)="en")}
  
 } group by ?concept ?euLabel ?euAltLabels ?esLabel ?esAltLabels ?enLabel ?enAltLabels
order by ?euLabel

Try it!

Euskarazko kontzeptu-etiketak Eustermen eta Wikidatan

Ikusteko, zer lexikalizazio dituen kontzeptu bakoitzak Eusterm-eko eskeman eta Wikidatan, erabili galdeketa hau. Wikidatako "prefLabel" eta "altLabel" Eusterm-eko etiketez ordeztea da ideia. 

PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>
PREFIX eusno: <https://eusterm.wikibase.cloud/prop/novalue/>

select ?concept ?eusterm_prefLabel
(group_concat(distinct str(?euAltLabel);SEPARATOR="; ") as ?eusterm_altLabels)  
# ?esLabel (group_concat(distinct str(?esAltLabel);SEPARATOR="; ") as ?esAltLabels)  
# ?enLabel (group_concat(distinct str(?enAltLabel);SEPARATOR="; ") as ?enAltLabels)  
?wd_uri ?wd_enPrefLabel ?wd_prefLabel ?wd_altLabels
where { #bind("Q5" as ?wikidata)
?concept eusdp:P6 euswb:Q194; eusdp:P1 ?wikidata ; rdfs:label ?eusterm_prefLabel . filter(lang(?eusterm_prefLabel)="eu") 

#   optional{?concept rdfs:label ?esLabel. filter(lang(?esLabel)="es")}
#   optional{?concept skos:altLabel ?esAltLabel. filter(lang(?esAltLabel)="es")}
#   optional{?concept rdfs:label ?enLabel. filter(lang(?enLabel)="en")}
#   optional{?concept skos:altLabel ?enAltLabel. filter(lang(?enAltLabel)="en")}

bind(iri(concat("http://www.wikidata.org/entity/",?wikidata)) as ?wd_uri)
SERVICE <https://query.wikidata.org/sparql> {    
select ?wd_uri ?wd_enPrefLabel ?wd_prefLabel (group_concat(distinct str(?wd_altLabel);SEPARATOR="; ") as ?wd_altLabels)  
WHERE { ?wd_uri rdfs:label ?wd_enPrefLabel. filter(lang(?wd_enPrefLabel)="en")
  optional{?wd_uri rdfs:label ?wd_prefLabel. filter(lang(?wd_prefLabel)="eu")}
  optional{?wd_uri skos:altLabel ?wd_altLabel. filter(lang(?wd_altLabel)="eu")}
} group by ?wd_uri ?wd_enPrefLabel ?wd_prefLabel ?wd_altLabels }
   
  optional{?concept skos:altLabel ?euAltLabel. filter(lang(?euAltLabel)="eu")}
     
 } group by ?concept ?eusterm_prefLabel
 ?eusterm_altLabels
?wd_uri ?wd_enPrefLabel ?wd_prefLabel ?wd_altLabels
order by ?eusterm_prefLabel

Try it!

Euskarazko definizioak Eustermen eta Wikidatan

Ikusteko, zer definizio kontzeptu bakoitzak Eusterm-eko eskeman eta Wikidatan, erabili galdeketa hau. Wikidatako definizioa Eusterm-eko definizioaz ordeztea da ideia. 

PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX euswb: <https://eusterm.wikibase.cloud/entity/>
PREFIX eusdp: <https://eusterm.wikibase.cloud/prop/direct/>
PREFIX eusp: <https://eusterm.wikibase.cloud/prop/>
PREFIX eusps: <https://eusterm.wikibase.cloud/prop/statement/>
PREFIX euspq: <https://eusterm.wikibase.cloud/prop/qualifier/>
PREFIX euspr: <https://eusterm.wikibase.cloud/prop/reference/>
PREFIX eusno: <https://eusterm.wikibase.cloud/prop/novalue/>

select ?concept ?eusterm_prefLabel ?eusterm_def
?wd_uri ?wd_enPrefLabel ?wd_euPrefLabel ?wd_def
where { 
?concept eusdp:P6 euswb:Q194; eusdp:P1 ?wikidata ; rdfs:label ?eusterm_prefLabel . filter(lang(?eusterm_prefLabel)="eu") 
bind(iri(concat("http://www.wikidata.org/entity/",?wikidata)) as ?wd_uri)
SERVICE <https://query.wikidata.org/sparql> {    
select ?wd_uri ?wd_enPrefLabel ?wd_euPrefLabel ?wd_def
WHERE { ?wd_uri rdfs:label ?wd_enPrefLabel. filter(lang(?wd_enPrefLabel)="en")
  optional{?wd_uri rdfs:label ?wd_euPrefLabel. filter(lang(?wd_euPrefLabel)="eu")}
  optional{?wd_uri schema:description ?wd_def. filter(lang(?wd_def)="eu")}
} group by ?wd_uri ?wd_enPrefLabel ?wd_euPrefLabel ?wd_def }
 optional{?concept schema:description ?eusterm_def. filter(lang(?eusterm_def)="eu")}
} group by ?concept ?eusterm_prefLabel ?eusterm_def
?wd_uri ?wd_enPrefLabel ?wd_euPrefLabel ?wd_def
order by ?eusterm_prefLabel

Try it!

Retrieved from "https://eusterm.wikibase.cloud/w/index.php?title=Astrologia&oldid=9404"